在ActionScript 3，如何可以通過數組的當前值在一個循環中一個事件監聽器

Question

代碼示例：

var gospels : Array = ["john", "mark", "matthew", "paul"]; 

for each (var book : String in gospels) 
{ 
    var loader : URLLoader = new URLLoader(); 
    loader.load(new URLRequest("http://example.com/" + name)); 

    trace(book) // outputs current value of array 

    loader.addEventListener(Event.COMPLETE, function(e : Event) : void { 
    trace(book); // prints paul 4 times 
    }); 
} 

我怎樣才能獲得該事件偵聽器來使用的數組的值循環何時調用事件偵聽器的函數？即當我在事件監聽器函數內部調用跟蹤時，我怎樣才能得到它輸出"john","mark",​​和"paul"？

Answer 1

var gospels:Array = ["john", "mark", "matthew", "paul"]; 

for each (var item:String in gospels) 
{ 
    (function(book:String){ 
    var loader : URLLoader = new URLLoader(); 
    loader.load(new URLRequest("http://example.com/" + name)); 

    trace(book) // outputs current value of array 

    loader.addEventListener(Event.COMPLETE, function(e:Event):void { 
     trace(book); // prints paul 4 times 
    }); 
    }(item)); 
} 

Answer 2

我覺得更優雅的方式是寫的URLLoader像一個超：

class MyURLLoader extends URLLoader { 
    public var book:String; 

    function MyURLLoader(aBook:String){ 
    book = aBook; 
    super(); 
    } 
} 

，然後在循環中使用這個類，如：

var gospels : Array = ["john", "mark", "matthew", "paul"]; 

for each (var book : String in gospels) 
{ 
    var loader : MyURLLoader = new MyURLLoader(book); 
    loader.load(new URLRequest("http://example.com/" + name)); 

    trace(book) // outputs current value of array 

    loader.addEventListener(Event.COMPLETE, function(e : Event) : void { 
    var myUrlLoader:MyURLLoader = e.target as MyURLLoader; 
    trace (myUrlLoader.book); 
    }); 
} 

附：我目前沒有使用閃存的電腦後面，所以我沒有機會檢查代碼。

Answer 3

邁克爾·布魯爾 - 戴維斯回答和變體，但在這裏使用Array.forEach以這種方式引入新的變量book每次迭代：

var gospels : Array = ["john", "mark", "matthew", "paul"]; 

gospels.forEach(function (book: String, i: int, a: Array): void { 
    var loader : URLLoader = new URLLoader(); 
    loader.load(new URLRequest("http://example.com/" + name)); 

    trace(book) // outputs current value of array 

    loader.addEventListener(Event.COMPLETE, function(e : Event) : void { 
    trace(book); 
    }); 
}); 

Answer 4

下面是做到這一點的最快最好的結構化的方式（IMO）：

var gospels:Array = ["john", "mark", "matthew", "paul"]; 

for(var book:String in gospels){ //For is faster than for each 
    var loader:URLLoader = new URLLoader(); 
    //It's good practise to add the event listener before calling the function 
    loader.addEventListener(Event.COMPLETE, loaderComplete(book), false, 0, true); 
    loader.load(new URLRequest("http://example.com/" + name)); 
} 

function loaderComplete(book:String):Function{ 
    return function(event:Event):void{ 
     event.target.removeEventListener(Event.COMPLETE, arguments.callee); 
     trace(book); 
    } 
}