Windows批處理For循環刪除空字符串到底

Question

我有以下代碼。顯示

@echo off 
setlocal EnableDelayedExpansion 
set holdingline=,Measure,,+ X,,,0,0 
FOR /F "tokens=1,2,3,4,5,6,7,8 delims=," %%a IN ("%holdingline%") DO (
    echo %%a 
    echo %%b 
    echo %%c 
    echo %%d 
    echo %%e 
    echo %%f 
    echo %%g 
    echo %%h 
    echo %holdingline% 
) 
pause 

輸出爲如下：

Measure 
+ X 
0 
0 
ECHO is off. 
ECHO is off. 
ECHO is off. 
ECHO is off. 
,Measure,,+ X,,,0,0 

空字符串推到結束，我不知道爲什麼。我期待他們爲了，這樣說：

ECHO is off. 
Measure 
ECHO is off. 
+ X 
ECHO is off. 
ECHO is off. 
0 
0 
,Measure,,+ X,,,0,0 

這將使我將它們分配給正確的變量。我嘗試搜索，但沒有找到太多的幫助。

Answer 1

@ECHO OFF 
SETLOCAL ENABLEDELAYEDEXPANSION 
set holdingline=,Measure,,+ X,,,0,0 
FOR /F "tokens=1-8 delims=," %%a IN (""%holdingline:,=","%"") DO (
    ECHO(%%~a 
    ECHO(%%~b 
    ECHO(%%~c 
    ECHO(%%~d 
    ECHO(%%~e 
    ECHO(%%~f 
    ECHO(%%~g 
    ECHO(%%~h 
    echo %holdingline% 
) 

GOTO :EOF 

這應該解決您的問題

---

要處理一個文件，生產新文件

@ECHO OFF 
SETLOCAL 
(
FOR /f "delims=" %%x IN (q29639243.txt) DO (
set "holdingline=%%x" 
CALL :process 
) 
)>u:\new.txt 

GOTO :EOF 

:process 
FOR /F "tokens=1-8 delims=," %%a IN (""%holdingline:,=","%"") DO (
    ECHO(%%~a 
    ECHO(%%~b 
    ECHO(%%~c 
    ECHO(%%~d 
    ECHO(%%~e 
    ECHO(%%~f 
    ECHO(%%~g 
    ECHO(%%~h 
    echo %holdingline% 
) 

GOTO :EOF 

我使用了含類似的數據爲我的測試命名爲q29639243.txt文件。 生產u：\ new.txt

Answer 2

這應該做你想讓它什麼：

@echo off 
setlocal EnableDelayedExpansion 
set holdingline=,Measure,,+ X,,,0,0 
FOR /F "tokens=1,2,3,4,5,6,7,8 delims=," %%a IN ("%holdingline:,,=, ,%") DO (
    echo %%a 
    echo %%b 
    echo %%c 
    echo %%d 
    echo %%e 
    echo %%f 
    echo %%g 
    echo %%h 
    echo %holdingline% 
) 
pause 

與, ,更換,,將導致它的中間變量設置爲（空間），因此對待他們像什麼。如果沒有這兩個,之間的任何東西它會跳過他們，因此只有4個變量存在，留下e-h空白