Listbox Userform VBA對單元格中的太多數據

Question

我在Excel 2007中的我的用戶表單中有一個小問題。我的工作表中的某些單元格包含1個單元格中的多於10行（帶有ALT ENTER的數據）。現在..即時通訊試圖找到一種方便，清潔的數據顯示。我不想將列寬更改爲1000，但我想用鼠標懸停在工具箱上顯示所有單元格數據。任何經驗豐富的人呢？或者也許是另一個想法

在此先感謝！

Answer 1

用鼠標將可能做到這一點，但它很複雜，我認爲。在這裏，我有另一個更簡單的想法：在列表框中雙擊一個多行文本框與選定列表項數據將顯示。該文本框與列表框具有相同的位置和大小。在用戶表單上單擊文本框隱藏。下面的示例代碼，以測試它，你需要有一個名爲「ListBox1的」列表框形成：

Option Explicit 

Public ListItemInfo As Control 

Private Sub UserForm_Initialize() 
    Set ListItemInfo = Me.Controls.Add("Forms.TextBox.1", "ListItemInfo", False) 
    With Me.ListItemInfo 
     .Top = Me.ListBox1.Top 
     .Left = Me.ListBox1.Left 
     .Width = Me.ListBox1.Width 
     .Height = Me.ListBox1.Height 
     .MultiLine = True 
    End With 
End Sub 

Private Sub ListBox1_Change() 
    Me.ListItemInfo.text = GetSelectedItemsText 
End Sub 

Private Sub ListBox1_DblClick(ByVal Cancel As MSForms.ReturnBoolean) 
    SwitchListItemInfo 
End Sub 

Private Sub UserForm_Click() 
    SwitchListItemInfo 
End Sub 

Private Function GetSelectedItemsText() As String 
    Dim text As String 
    Dim i As Integer 
    For i = 0 To Me.ListBox1.ListCount - 1 
     If Me.ListBox1.Selected(i) Then 
      text = text & Me.ListBox1.List(i) & vbNewLine 
     End If 
    Next i 
    GetSelectedItemsText = text 
End Function 

Private Sub SwitchListItemInfo() 
    If Me.ListItemInfo.text = "" Then Exit Sub 
    Me.ListItemInfo.Visible = Not Me.ListItemInfo.Visible 
    Me.ListBox1.Visible = Not Me.ListBox1.Visible 
End Sub