Parse :: RecDescent - 從中獲取信息

我正在使用Perl中的Parse::RecDescent解析器，而且我似乎從中獲取信息的時間最爲可怕。網上很容易獲得的信息似乎沒有不平凡的例子。Parse :: RecDescent - 從中獲取信息

下面是代碼：

event_function: object_list ':' event_list ';' 
     <defer: 
     {  #item is a special character with Parse::Recdescent. 
      print Dumper($item{object_list}); 
      $return = $item[1]; 
     } 
     > 
     | object_list ':' ';' 
     <defer: 
     { 
      print Dumper($item{object_list}); 
      $return = $item[1]; 
     } 
     >

下面是輸入文件解析正確的輸出

PS W:\developers\paulnathan\rd_dir> perl parser.pl testfile 
$VAR1 = 4; 
$VAR1 = 8; 
PS W:\developers\paulnathan\rd_dir>

。

stuff, stuff2: pre-operation event = {foo1, foo2};

它應該來輸出由「東西」，「stuff2」鍵哈希值。

想法？

編輯：

object_list : 
     object ',' object_list 
     <defer: 
     { 

      my $retval =(); 
      $retval = ::merge_hash_refs($item[1], $item[3]); 

      $return = $retval; 
     } 
     > 
     | object 
     <defer: 
     { 
      #print Dumper($item{object}); 
      $return = $item{object}; 
     } 
     >  

    object : 
     '/' /[a-z0-9_][a-z0-9_]*/ '/' '...' 
      <defer: 
      { 
       $::objects->{$item[2]} = "stuff"; 
       $return = $::objects; 
      } 
      > 
     | /[a-z0-9_][a-z0-9_]*/ 
      <defer: 
      { 
       $::objects->{$item[1]} = "stuff"; 
       $return = $::objects; 
      } 
      >

EDIT2： Merge_hash_refs，以防萬一。 :-)

#takes two hash references. 
sub merge_hash_refs { 
    my($ref1, $ref2) = @_; 
    my $retref =(); 
    while(my ($k, $v) = each %$ref1) { 
     $retref->{$k} = $v; 
    } 
    while(my ($k, $v) = each %$ref2) { 
     $retref->{$k} = $v; 
    } 

    return $retref; 
}

來源

2009-06-04 Paul Nathan

你能顯示object_list和event_list規則的內容嗎？ – 2009-06-04 16:38:28

Event_list不返回任何內容;添加了object_list。 – 2009-06-04 16:40:03

如果添加use strict到你的腳本，你會得到致命錯誤無法使用字符串（「1」）作爲HASH裁判而「嚴格裁判」在使用中[在致電merge_hash_refs]。看起來，由<defer>指令創建的閉包導致@item的內容是生產匹配時的內容，而不是最終由子規則返回的hashrefs。卸下<defer>指令給了我這樣的輸出：

$VAR1 = { 
      'stuff2' => 'stuff', 
      'stuff' => 'stuff' 
     };

當然，這有副作用，就是$ ::目標是通過成功的object作品更新，即使更高級別規則失敗（包括回溯）。我會寫這樣說：

use strict; 
use warnings; 
use Parse::RecDescent; 
use Data::Dumper; 

my $parser = Parse::RecDescent->new(<<'EOT'); 
event_function: object_list ':' event_list(?) ';' 
    { 
     $return = $item[1]; 
    } 

object_list : <leftop: object ',' object> 
    { 
     $return = { map { %$_ } @{$item[1]} }; 
    } 

object : 
    '/' /[a-z0-9_][a-z0-9_]*/ '/' '...' 
     { 
      $return = { $item[2] => 'stuff' }; 
     } 
    | /[a-z0-9_][a-z0-9_]*/ 
     { 
      $return = { $item[1] => 'stuff' }; 
     } 

# stub, don't know what this should be 
event_list : /[^;]+/ 

EOT 

my %object; 

while (<DATA>) { 
    my $x = $parser->event_function($_); 

    next unless $x; 

    # merge objects into master list 
    while (my ($k, $v) = each %$x) { 
     $object{$k} = $v; 
    } 
} 

print Dumper \%object; 

__DATA__ 
stuff, stuff2: pre-operation event = {foo1, foo2}; 
stuff3, stuff4: ;

輸出是：

$VAR1 = { 
      'stuff2' => 'stuff', 
      'stuff3' => 'stuff', 
      'stuff' => 'stuff', 
      'stuff4' => 'stuff' 
     };

來源

2009-06-04 17:26:00

這使一種邪惡的感覺。嘆。謝謝。 – 2009-06-04 17:44:31

大概不會回答你的問題，但是當你通過散列開始的每一個（）循環，如果每個（）之前已經用在散列上，它只是從迭代器指向的任何地方開始。爲了安全起見，在while循環之前放置一個void-context keys（）（例如鍵（％$ ref1）;）來重置迭代器。較早版本的Data :: Dumper有一個可愛的小錯誤，它使得迭代器有時會指向最後一個元素，使得哈希似乎是空的（while ...（... each循環））：

來源

2009-06-04 17:26:53 ysth

Parse :: RecDescent - 從中​​獲取信息

回答

相關問題

Parse :: RecDescent - 從中獲取信息