播放聲音，傳遞URL到閃存

Question

如果我有一個URL到一個MP3，我可以通過這種方式到一個Flash文件，以便它會播放它？我怎麼能這樣做？

Answer 1

從actionscript reference一個例子：

package { 
    import flash.display.Sprite; 
    import flash.events.*; 
    import flash.media.Sound; 
    import flash.media.SoundChannel; 
    import flash.net.URLRequest; 

    public class SoundExample extends Sprite { 
     private var url:String = "MySound.mp3"; 
     private var song:SoundChannel; 

     public function SoundExample() { 
      var request:URLRequest = new URLRequest(url); 
      var soundFactory:Sound = new Sound(); 
      soundFactory.addEventListener(Event.COMPLETE, completeHandler); 
      soundFactory.addEventListener(Event.ID3, id3Handler); 
      soundFactory.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler); 
      soundFactory.addEventListener(ProgressEvent.PROGRESS, progressHandler); 
      soundFactory.load(request); 
      song = soundFactory.play(); 
     } 

     private function completeHandler(event:Event):void { 
      trace("completeHandler: " + event); 
     } 

     private function id3Handler(event:Event):void { 
      trace("id3Handler: " + event); 
     } 

     private function ioErrorHandler(event:Event):void { 
      trace("ioErrorHandler: " + event); 
     } 

     private function progressHandler(event:ProgressEvent):void { 
      trace("progressHandler: " + event); 
     } 
    } 
} 

您可以在上面結合與LoaderInfo的參數：這些都是通過HTML或參數用來調用swf的網址通過Flash變數。

在參考文獻中有很多很好的例子，我主要通過gotoandlearn.com和the reference瞭解到actionscript。

Answer 2

通過設置flashvar，您可以設置將url傳遞給swf。你可以用兩種方式設置flashvars ..使用嵌入代碼上的param元素，或者你可以將它們追加到swf的url，結果是一樣的。

http://blog.six4rty.ch/tutorials/flash-flashvars-in-as3/

如果你不知道的MP3鏈接，當你加載你必須使用ExternalInterface ActionScript方法來註冊一些動作功能，所以你可以從網頁上的JavaScript調用他們瑞士法郎。因此，在您的Flash影片，你可以有

function setSrc(mp3URL) { ... } 
function play(){ ... } 
function stop(){ ... } 

寄存器每一種與外部接口

ExternalInterface.addCallback('setSrc', setSrc); 
ExternalInterface.addCallback('play', play); 
ExternalInterface.addCallback('stop', stop); 

現在你可以從JavaScript中使用它們。