我怎樣才能得到一個Microsoft Access組合框的行爲像一個列表框

Question

當你點擊一個字母的列表框，它會帶你到該字母的第一個匹配。當你再次點擊該字母時，會將你帶到該字母的第二個匹配項等等。

有沒有辦法讓組合框的行爲方式？

Answer 1

我能想到的最接近的組合框是自動完成屬性。

Answer 2

其實，用組合框當你點擊一個字母，它把你的第一場比賽爲字母或從下拉框中選擇......並用列表框你必須從選擇拉下。我想你的問題反過來了。你可能只需要讓你的領域是組合框而不是列表框。

Answer 3

除非您想對組合框進行編碼，否則無法使組合框的行爲如此。但是，編碼並不是那麼糟糕。下面的代碼可能可以改進（並且至少應該添加一些錯誤處理），但它會完成工作。

假設你有OnKeyPress名爲ComboBox1一個組合框和OnKeyDown，窗體和OnKeyUp屬性都設置爲[Event Procedure]：

Private Sub Combo1_KeyDown(KeyCode As Integer, Shift As Integer) 
Dim Cbo As ComboBox, i As Integer, Val As Variant, CurIndex As Integer 
    Set Cbo = Me.ActiveControl 
    Select Case KeyCode 
    Case vbKeyBack, vbKeyDelete 
     Cbo.Value = Null 
    Case Else 
     CurIndex = Cbo.ListIndex 
     For i = CurIndex + 1 To Cbo.ListCount - 1 
      If Left(Cbo.ItemData(i), 1) = Chr(KeyCode) Then 
       Cbo.Value = Cbo.ItemData(i) 
       Exit Sub 
      End If 
     Next i 
     For i = 0 To CurIndex 
      If Left(Cbo.ItemData(i), 1) = Chr(KeyCode) Then 
       Cbo = Cbo.ItemData(i) 
       Exit Sub 
      End If 
     Next i 
    End Select 
    KeyCode = StripKeyCode(KeyCode) 
End Sub 

Private Sub Combo1_KeyPress(KeyAscii As Integer) 
    KeyAscii = StripKeyCode(KeyAscii) 
End Sub 

Private Sub Combo1_KeyUp(KeyCode As Integer, Shift As Integer) 
    KeyCode = StripKeyCode(KeyCode) 
End Sub 

Private Function StripKeyCode(KeyCode As Integer) As Integer 
    Select Case KeyCode 
    Case vbKeyUp, vbKeyDown, vbKeyLeft, vbKeyRight, vbKeyTab, vbKeyF4 
     'Allow navigation keys to pass through 
     StripKeyCode = KeyCode 
    Case Else 
     StripKeyCode = 0 
    End Select 
End Function 

我懷疑的表現將是所有偉大與組合框一大堆的選擇。然後，再次，您應該只能在以相同字母開頭的項目數量很小（例如，小於5）的情況下使用這種技術。