常規方式將列表中的每個元素進行配對

Question

每個元素應該相互配對，但只能配對一次。

給出一個列表A, B, C我想要對下面的列表：(A,B), (A,C), (B,C)

同樣4元A, B, C, D結果應該是(A,B), (A,C), (A,D), (B,C), (B,D), (C,D)。

我試着用每個Permutation，eachCombintation但是找不到一個好方法。如果你能告訴我這個操作的基本名稱是什麼，那將是一個很大的幫助。

Answer 1

有點晚了，但似乎subsequences會很快解決這個問題。它提供了多對，但限制結果集對於將來的讀者來說將是微不足道的和明顯的：

def pairs(def l) { 
    l.subsequences().findAll {it.size() == 2} 
} 
assert pairs(['a','b','c']) == [['a','b'], ['a','c'], ['b', 'c']] as Set 
assert pairs(['a', 'b', 'c', 'd']) == [['a', 'b'], ['a', 'c'], ['a', 'd'], ['b', 'c'], ['b', 'd'], ['c', 'd']] as Set 

Answer 2

如何做遞歸？第一個元素和尾部的組合，然後在列表的其餘部分進行遞歸。

def comb(l,r=[]) { 
    if (l) { 
     r.addAll([l.head(), l.tail()].combinations()) 
     return comb(l.tail(), r) 
    } 
    return r 
} 

def m = ['a','b','c','d'] 
def result = comb(m) 
assert result == [['a', 'b'], ['a', 'c'], ['a', 'd'], ['b', 'c'], ['b', 'd'], ['c', 'd']] 

Answer 3

可以使用combinations，toSet，sort和findAll剩下的，其大小等於2：

def uniqueCombinations = { l -> 
    [l,l].combinations()*.toSet()*.sort().unique().findAll { it.size() == 2 } 
} 

l=[1,2,3] 
assert uniqueCombinations(l) == [[1, 2], [1, 3], [2, 3]] 

Answer 4

有可能沒有這樣的在Groovy中的一個功能，但你可以很容易地實現它：

def pairs(def elements) { 
    return elements.tail().collect { [elements.head(), it] } + (elements.size() > 1 ? pairs(elements.tail()) : []) 
} 

assert pairs(['A', 'B', 'C']) == [['A', 'B'], ['A', 'C'], ['B', 'C']] 
assert pairs(['A', 'B', 'C', 'D']) == [['A', 'B'], ['A', 'C'], ['A', 'D'], ['B', 'C'], ['B', 'D'], ['C', 'D']] 

Answer 5

與eachCombination它會是：

def l = ['A', 'B', 'C', 'D'], result = [] 

[l, l].eachCombination { 
    if (! (it in result*.intersect(it) || it[0] == it[1])) { 
     result << it.reverse() 
    } 
} 

assert result == [ 
    ['A', 'B'], ['A', 'C'], ['A', 'D'], ['B', 'C'], ['B', 'D'], ['C', 'D'] 
]