將數據庫中的值放入下拉列表

我的工具是在asp中。我正在使用此代碼在sql查詢將數據庫中的值放入下拉列表

dim req_id 
req_id=Request.Form("Req_id") 

if req_id<>"" then 
Set conn=server.CreateObject("adodb.connection") 
        conn.Open session("Psrconnect") 
        Set rs=CreateObject("Adodb.Recordset") 
        rs.Open "select * from passwords where REQ_ID='"&req_id&"'", conn

我想將此查詢的結果放入下拉列表中。我該怎麼做？很感謝任何形式的幫助。從我的工作頁面

來源

2010-06-03 sushant

略加編輯代碼：

function HtmlFormOption(byval psReturnValue, byval psDisplayValue ,byval psCurrentDefault) 
    dim x 
    if IsNull(psCurrentDefault) then psCurrentDefault = "" 
    if IsNull(psReturnValue) then psReturnValue = "" 

    if lCase(cStr(psReturnValue)) = lCase(cStr(psCurrentDefault)) then 
     x = "selected " 
    else 
     x = "" 
    end if 
    HtmlFormOption = "<option " & x & "value='" & psReturnValue & "'>" & psDisplayValue & "</option>" 
end function 

    dim Result, sCode, sWaarde 
    Result = "<select name='NameCombobox' size='1'>" & vbCrlf 
    while not objRecLookup.Eof 
     sCode = objRecLookup.Fields(0) ' first field in result set 
     sWaarde = objRecLookup.Fields(1) ' second field in result set 
     if not IsNull(sCode) and not IsNull(sWaarde) then 
     Result = Result & HtmlFormOption(sCode, sWaarde , psCurrentDft) 
     end if 
     objRecLookup.MoveNext 
    wend 
    objRecLookup.Close 
    Result = Result & "</select>" & vbCrlf

而且比Response.Write(Result)

來源

2010-06-03 10:50:50 Edelcom

這裏有一個簡單的解決方案：

<% 

Dim objCommand, objRS 
Set objCommand = Server.CreateObject("ADODB.Command") 

with objCommand 
    .ActiveConnection = objConn 
    .CommandType = adCmdText 
    .CommandText = "SELECT * FROM PASSWORDS WHERE REQ_ID= '" & req_id & "'" 
    Set objRS = .Execute 
end with 

%><select name="selectbox"><% 

While NOT objRS.EOF 
    %><option value="<%=objRS("COLUMN_NAME")%>"><%=objRS("COLUMN_NAME")%></option><% 
    objRS.MoveNext 
Wend 

%></select><% 

objRS.Close 
Set objRS = Nothing 
Set objCommand = Nothing 

%>

來源

2010-07-08 01:27:46

將數據庫中的值放入下拉列表

回答

相關問題