批處理文件乘上正變量返回一個負數

我一直在批處理多邊形面積計算器，我遇到了問題。我需要乘以2個變量，但有時它會返回一個負數，如果這兩個正變量很大。批處理文件乘上正變量返回一個負數

下面是一個例子：999999*999999返回-729379967。

代碼低於：

REM Calc square area 
:PolySqu 
Cls 
Echo          Polygon Area Calculator 
For /L %%P In (1,1,57) Do Echo. 
Set /P "InputPolygonCalSqu=Enter one of the line's length in cm :" 


Set /A SquArea=InputPolygonCalSqu * InputPolygonCalSqu 


Cls 
Echo          Polygon Area Calculator 
For /L %%P In (1,1,57) Do Echo. 
Echo The area of this square is %SquArea% cm2. 
Pause 
Goto :PolygonCal

似乎命令

Set /A SquArea="InputPolygonCalSqu * InputPolygonCalSqu

不能正確計算。

來源

2016-07-25 SteveFest

這是我永遠不會建議使用PowerShell中的問題而與[批處理文件]中只有兩種情況之一標籤。 – SomethingDark

http://stackoverflow.com/questions/38579524/how-do-i-use-basic-batch-math-commands-to-come-up-with-decimal-answers/38579735#38579735對於使用雙精確浮動數學。 – 2016-07-26 03:37:59

@Noodles謝謝你的解答，我已經指出了這個問題。 – SteveFest

正如其他人已經指出，一個batch-file本身僅支持32位有符號整數運算。

下面的代碼構成一個變通爲乘以更大的非負數比2 − 1 = 2147483647的限制，使用純batch-file命令（我們稱之爲multiply.bat）：

@echo off 
setlocal EnableExtensions DisableDelayedExpansion 

rem // Define arguments here: 
set "NUM1=%~1" 
set "NUM2=%~2" 
set "NUM3=%~3" 
set "NUM4=%~4" 
if defined NUM1 set "NUM1=%NUM1:"=""% 
if defined NUM2 set "NUM2=%NUM2:"=""% 
if defined NUM3 set "NUM3=%NUM3:"=% 
call :VAL_ARGS NUM1 NUM2 NUM4 || exit /B 1 

rem // Define constants here: 
set /A "DIG=4" & set "PAD=" 
setlocal EnableDelayedExpansion 
for /L %%J in (1,1,%DIG%) do set "PAD=!PAD!0" 
endlocal & set "PAD=%PAD%" 

rem // Determine string lengths: 
call :STR_LEN LEN1 NUM1 
call :STR_LEN LEN2 NUM2 
set /A "LEN1=(LEN1-1)/DIG*DIG" 
set /A "LEN2=(LEN2-1)/DIG*DIG" 
set /A "LIM=LEN1+LEN2+DIG" 
for /L %%I in (0,%DIG%,%LIM%) do set /A "RES[%%I]=0" 

rem // Perform block-wise multiplication: 
setlocal EnableDelayedExpansion 
for /L %%J in (0,%DIG%,%LEN2%) do (
    for /L %%I in (0,%DIG%,%LEN1%) do (
     set /A "IDX=%%I+%%J" 
     if %%I EQU 0 (set "AUX1=-%DIG%") else (
      set /A "AUX1=%DIG%+%%I" & set "AUX1=-!AUX1!,-%%I" 
     ) 
     if %%J EQU 0 (set "AUX2=-%DIG%") else (
      set /A "AUX2=%DIG%+%%J" & set "AUX2=-!AUX2!,-%%J" 
     ) 
     for /F "tokens=1,2" %%M in ("!AUX1! !AUX2!") do (
      set "AUX1=!NUM1:~%%M!" & set "AUX2=!NUM2:~%%N!" 
     ) 
     call :NO_LEAD0 AUX1 !AUX1! 
     call :NO_LEAD0 AUX2 !AUX2! 
     set /A "RES[!IDX!]+=AUX1*AUX2" 
     set /A "NXT=IDX+DIG, DIT=DIG*2" 
     for /F "tokens=1,2,3" %%M in ("!IDX! !NXT! !DIT!") do (
      set "AUX=!RES[%%M]:~-%%O,-%DIG%!" 
      set /A "RES[%%N]+=AUX" 
      set "RES[%%M]=!RES[%%M]:~-%DIG%!" 
      call :NO_LEAD0 RES[%%M] !RES[%%M]! 
     ) 
    ) 
) 

rem // Build resulting product: 
set "RES=" & set "AUX=" 
for /L %%I in (0,%DIG%,%LIM%) do (
    set /A "RES[%%I]+=AUX" 
    set /A "NXT=%%I+DIG" 
    for /L %%J in (!NXT!,%DIG%,!NXT!) do (
     set "AUX=!RES[%%I]:~-%%J,-%DIG%!" 
    ) 
    set "RES[%%I]=%PAD%!RES[%%I]!" 
    set "RES=!RES[%%I]:~-%DIG%!!RES!" 
) 
endlocal & set "RES=%RES%" 
call :NO_LEAD0 RES %RES% 

rem // Return resulting product: 
echo(%RES% 
if defined NUM3 (
    endlocal 
    set "%NUM3%=%RES%" 
) else (
    endlocal 
) 
exit /B 


:NO_LEAD0 rtn_var val_num 
rem // Remove leading zeros from a number: 
for /F "tokens=* delims=0" %%Z in ("%~2") do (
    set "%~1=%%Z" & if not defined %~1 set "%~1=0" 
) 
exit /B 0 


:STR_LEN rtn_length ref_string 
rem // Retrieve length of string: 
setlocal EnableDelayedExpansion 
set "STR=!%~2!" 
if not defined STR (set /A LEN=0) else (set /A LEN=1) 
for %%L in (4096 2048 1024 512 256 128 64 32 16 8 4 2 1) do (
    if defined STR (
     set "INT=!STR:~%%L!" 
     if not "!INT!"=="" set /A LEN+=%%L & set "STR=!INT!" 
    ) 
) 
endlocal & set "%~1=%LEN%" 
exit /B 0 


:VAL_ARGS ref_arg1 ref_arg2 ref_arg3 
rem // Check arguments for validity: 
if not defined %~1 >&2 echo ERROR: too few arguments given! & exit /B 1 
if not defined %~2 >&2 echo ERROR: too few arguments given! & exit /B 1 
if defined %~3 >&2 echo ERROR: too many arguments given! & exit /B 1 
(call echo "%%%~1%%" | > nul findstr /R /C:"^\"[0-9][0-9]*\" $") || (
    >&2 echo ERROR: argument 1 is not purely numeric! & exit /B 1 
) 
(call echo "%%%~2%%" | > nul findstr /R /C:"^\"[0-9][0-9]*\" $") || (
    >&2 echo ERROR: argument 2 is not purely numeric! & exit /B 1 
) 
exit /B 0

要使用它提供兩個數字作爲命令行參數相乘;例如：

multiply.bat 999999 999999

將得到的產品在控制檯上返回：

999998000001

如果提供第三個參數，該產品被分配到與該名稱的變量;例如：

multiply.bat 999999 999999 SquArea

這將變量SquArea設置爲結果值。後者還在控制檯上返回。
要靜悄悄地分配變量沒有任何額外的控制檯輸出，重定向到nul設備：

multiply.bat 999999 999999 SquArea > nul

來源

2016-07-25 20:13:23 aschipfl

也許您可能對[此解決方案]感興趣（http://stackoverflow.com/a/38579834）... – aschipfl

批量使用32位整數存儲數字。這給了他們最大的大小2^31 - 1 = 2,147,483,647。

999,999 * 999,999 = 999,998,000,001大於2,147,483,647，因此它「隱藏」並從負數開始。

這是批次的限制，雖然有一些workarounds。

來源

2016-07-25 14:45:33 BrandonM

這可能是

Can batch files not process large numbers?

最大數目批次可以是2^31有用 - 1 = 2147483647。

所以，再一次，它開始由負回給你的答案..

來源

2016-07-25 14:48:39 Bharath

我使用純批註意到，這將是多少有點很難實現支持超過32位整數的數字運算限制。相反，我限制了數字，所以它們不會在倍增時溢出。

REM Calc Square Area 
:PolySqu 
Cls 
Echo      Polygon Area Calculator 
For /L %%P In (1,1,57) Do Echo. 
Set /P "InputPolygonCalSqu=Enter one of the line's length in cm [Less then 40000] :" 
If %InputPolygonCalSqu% GTR 40000 Goto :PolySqu 

Set /A SquArea="InputPolygonCalSqu * InputPolygonCalSqu 


Cls 
Echo      Polygon Area Calculator 
For /L %%P In (1,1,57) Do Echo. 
Echo The area of this square is %SquArea% cm2. 
Pause 
Goto :PolygonCal

來源

2016-07-25 15:05:17 SteveFest

批處理文件乘上正變量返回一個負數

回答

相關問題