如何實例化具有相似/相同功能但屬性不同的對象？

Question

AS3的新手，長時間的程序員。本質上，我創建了無數的對象，所有這些對象都具有相同的功能，但屬性在每個對象（包括藝術品）之間會有所不同。我相信他們都將成爲影片剪輯，因爲他們將會互動，我相信他們將會移動。

我想知道什麼是創建這些對象的最佳方法。我假設我創建了一個具有功能和屬性的對象類，我只是不確定如何實例化具有不同屬性的多個副本，如果這是有道理的。

對不起，我可以幫忙詳細說明，如果有必要，並提前感謝您的幫助！ :)

Answer 1

創建一個班級。

package { 
    import flash.display.MovieClip; 

    public class MyMovieClip extends MovieClip { 
    } 
} 

添加可能會有所不同的屬性。

package { 
    import flash.display.DisplayObject; 
    import flash.display.MovieClip; 

    public class MyMovieClip extends MovieClip { 
     private var _borderColor : uint; 
     private var _artWork : DisplayObject; 
    } 
} 

增加修改屬性的可能性。你可以使用構造函數參數或明確的getter/setter，或者你可以聲明你的屬性是公開的。

package { 
    import flash.display.DisplayObject; 
    import flash.display.MovieClip; 

    public class MyMovieClip extends MovieClip { 
     private var _borderColor : uint; 
     private var _artWork : DisplayObject; 

     // using constructor parameters 

     public function MyMovieClip(borderColor : uint, artWork : DisplayObject) { 
      _borderColor = borderColor; 
      _artWork = artWork; 
     } 

     // using setter/getter 

     public function set borderColor(borderColor : uint) : void { 
      _borderColor = borderColor; 
     } 

     public function get borderColor() : uint { 
      return _borderColor; 
     } 

     public function set artWork(artWork : DisplayObject) : void { 
      _artWork = artWork; 
     } 
     public function get artWork() : DisplayObject { 
      return _artWork; 
     } 

    } 
} 

創建類的實例，並使用不同的值設置它們：

package { 
    import flash.display.Shape; 
    import flash.display.Sprite; 

    public class Main extends Sprite { 
     public function Main() { 
      var myMc1 : MyMovieClip = new MyMovieClip(0xFF0000, new Shape()); 
      var myMc2 : MyMovieClip = new MyMovieClip(0x0000FF, new Shape()); 
      var myMc3 : MyMovieClip = new MyMovieClip(0x00FF00, new Shape()); 

      myMc1.borderColor = 0xFF0000; 
      myMc3.artWork = new Shape(); 
     } 
    } 
} 

Answer 2

在AS3中，Object類在其修飾符中標記爲動態，隨後可以動態添加任何您想要的屬性。此外，類似地，您可以製作自己的類，並將其標記爲動態，然後爲其添加屬性，以便正確評估如何使用這些屬性，儘管可能不值得複雜化，但最好是使不同不同類型的對象的類。如果他們共享一些基本功能，那麼您可以先創建一個基類併爲每個特定類型的對象擴展它。

瞭解更多關於動態的關鍵字： http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/statements.html?filter_flash=cs5&filter_flashplayer=10.2&filter_air=2.6#dynamic

但是正如我所說以上，我認爲延長可能是一個更好的方法來實現你想要做什麼......而且我是一個大的倡導者使用Flex框架使AS3更容易，無論如何更多的OOP與AS3在這裏： http://www.adobe.com/devnet/actionscript/articles/oop_as3.html

讓我知道這是否有幫助，或者你正在尋找別的東西。