SAS：重命名宏目錄

Question

我想將宏存儲在目錄中。這樣做可以讓許多宏只與一個文件共享，並且引入了與用戶分離的程度。

來存儲我的宏，我運行一個程序，如

/* HelloWorld.sas */ 
libname pwd ".";    /* assign current directory */ 
option mstored sasmstore=pwd; /* set pwd as storage directory */ 

%macro HelloWorld() 
    /store source;   /* store compiled macro along with its source */ 
    data _null_; 
    put "Hello, World!"; 
    run; 
%mend; 

這在目錄中創建一個sasmacr.sas7bcat文件，在其中HelloWorld.sas生活。然後我可以在文件移動到另一個目錄，如C:\myMacros和運行下面的程序：

/* CallHelloWorld.sas */ 
libname myMacros 'C:\myMacros'; 
option mstored sasmstore=myMacros; 

%HelloWorld(); 

宏HelloWorld()被稱爲沒有錯誤。但是，如果我想將HelloWorld()宏作爲「HelloWorld」宏套件的一部分，我不能簡單地將Windows資源管理器中的目錄名稱從sasmacr.sas7bcat更改爲HelloWorld.sas7bcat。當我這樣做並嘗試再次運行CallHelloWorld.sas（關閉並重新打開SAS後），宏未解析。

1 /* CallHelloWorld.sas */ 
2 libname myMacros 'C:\myMacros'; 
NOTE: Libref MYMACROS was successfully assigned as follows: 
     Engine:  V9 
     Physical Name: C:\myMacros 
3 option mstored sasmstore=myMacros; 
4 
5 %HelloWorld(); 
    - 
    180 
NOTE: The SAS System was unable to open the macro library referenced by the SASMSTORE = libref 
     MYMACROS. 
WARNING: Apparent invocation of macro HELLOWORLD not resolved. 

ERROR 180-322: Statement is not valid or it is used out of proper order. 

ERROR: Catalog MYMACROS.SASMACR does not exist. 
NOTE: The SAS System was unable to open the macro library referenced by the SASMSTORE = libref 
     MYMACROS. 
ERROR: An error occurred during the execution of the %COPY statement. 

如何更改包含宏的目錄的名稱，以便可以在各種程序中調用這些宏？是否可以預先命名目錄與sasmacr不同？

Answer 1

我不認爲你可以將目錄從SASMACR重命名，並仍然直接使用它。但是，您可以使用PROC CATALOG來管理SASMACR目錄。

你想要做的是，當你想包括一個特定的宏，將它從proc catalog從其源位置複製到您選擇的SASMSTORE位置。

喜歡的東西：

libname myMacros 'C:\temp'; 
libname pwd '.'; 

options mstored sasmstore=pwd; 

proc catalog catalog=myMacros.HelloWorld; 
    copy out=pwd.sasmacr; 
run; 
quit; 


%HelloWorld(); 

現在 - 我建議這可能是矯枉過正;真的沒有理由以這種方式分開的宏目錄。如果您喜歡單獨包含文件的想法，您可能需要考慮Autocall宏（您不會將它們存儲爲已編譯，但存儲它們的源代碼和按需編譯）;無論如何，真正編譯一個宏在SAS中幾乎沒有任何成本。但是如果使用存儲編譯的宏是你喜歡的，那麼這種方法可能是最好的方法。

當然，我認爲更簡單的方法是離開目錄SASMACR.SAS7BCAT並使用目錄名稱來確定它是什麼，然後將librefs附加到您的sasmstore選項值。

Answer 2

至少在使用SAS 9.4的Unix上，您可以使用SASAUTOS選項指向使用ZIP引擎的FILEREF，以便將所有宏定義存儲在一個ZIP文件中。

一個「訣竅」是，您需要更改ZIP文件中成員文件的名稱。通常在Unix上，SASAUTOS要求源文件使用小寫的宏名稱命名，其.sas擴展名（helloworld.sas）。但是，對於SASAUTOS使用ZIP文件，應該使用大寫字母的名稱以NO擴展名（HELLOWORLD）命名成員。

filename mymacros zip '~/mymacros.zip'; 
options insert=(sasautos=(mymacros)) ; 

EDIT

不幸的是這種方法會導致SAS生成錯誤：消息時在ZIP文件中沒有找到宏源文件，即使是在SASAUTOS選項另一個文件最終發現搜索路徑。

Answer 3

從DATA_NULL_我已收到如何使用具有不同名稱的現有目錄的答案。使用CATNAME語句。所以如果你有目錄TEST.CAT1和TEST.CAT2，你可以使用CATNAME語句來使TEST.SASMACR成爲兩個宏的連接。

CATNAME test.sasmacr 
    (test.cat1 (ACCESS=READONLY) 
    test.cat2 (ACCESS=READONLY) 
) 
; 

您現在可以將SASMSTORE選項指向TEST libref。

option mstored sasmstore=test; 

這裏是你如何可以創建使用PROC CATALOG來複制已經被編譯成一個SASMACR目錄與名稱不同的目錄成員這樣的單獨目錄的例子。

libname templib '~/test/cat1'; 
libname permlib '~/test'; 
options mstored sasmstore=templib; 

%macro HelloWorld1()/store source; 
    data _null_; 
    put "Hello, World! &sysmacroname"; 
    run; 
%mend; 

%macro HelloWorld2()/store source; 
    data _null_; 
    put "Hello, World! &sysmacroname"; 
    run; 
%mend; 

proc catalog cat=templib.sasmacr ; 
    copy out=permlib.cat1; 
     select helloworld1 /et=macro; 
    run; 
    copy out=permlib.cat2; 
     select helloworld2 /et=macro; 
    run; 
quit; 

現在使用CATNAME命令將目錄鏈接在一起。

options mstored sasmstore=permlib; 
CATNAME permlib.sasmacr 
    (permlib.cat1 (ACCESS=READONLY) 
    permlib.cat2 (ACCESS=READONLY) 
); 

%helloworld1; 
%helloworld2;