在訪問找到一個隨機記錄（真隨機）

Question

我想要做的是每次程序打開窗體上的圖像是不同的。所以我有一個帶有2列ID和ImagePath的簡單表，我如何創建代碼以便在表單加載事件或類似的事件上選擇一個隨機記錄（ImagePath）？ Rnd是不好的，因爲每次數據庫重新打開時它都是相同的圖像。

謝謝！

Answer 1

查看TechRepublic的這篇文章由蘇珊·哈金斯：http://www.techrepublic.com/blog/howdoi/how-do-i-retrieve-a-random-set-of-records-in-microsoft-access/149

我在此查詢，它每次返回不同的記錄中使用她的GetRandomValue功能。

SELECT TOP 1 f.id, GetRandomValue(f.id) AS rnd_value 
FROM tblFoo AS f 
ORDER BY 2; 

功能：

Public Function GetRandomValue(fld As Variant) 

    Randomize 

    GetRandomValue = Rnd(1) 

End Function 

注意：這種方法需要運行對錶的每一行的功能。對於中小型餐桌，這可能是可以忍受的。但是你不應該在非常大的表格中使用它。

Answer 2

嘗試調用Randomize一次 - 在第一次調用Rnd之前。正如Rnd的幫助主題所說：「在調用Rnd之前，使用沒有參數的Randomize語句來使用基於系統定時器的種子初始化隨機數生成器。」

Answer 3

Rnd不好？

Option Compare Database 
Option Explicit 

Sub Test() 
    Randomize 
    Dim x As Integer 
    'Print the first field of a 100 random records 
    For x = 0 To 100 
     CallRandomRecord 
    Next x 
End Sub 

Sub CallRandomRecord() 
    Dim rs As DAO.Recordset 
    Dim recordCount As Long 
    Dim randomRecord As Long 

    Set rs = CurrentDb.OpenRecordset("SELECT * FROM MyTable") 
    rs.MoveLast 'To get the count 
    rs.MoveFirst 
    recordCount = rs.recordCount - 1 
    randomRecord = CLng((recordCount) * Rnd) 

    rs.Move randomRecord 

    Debug.Print "Random Record No:" & randomRecord & " Field 1: " & rs.Fields(0) 

End Sub 

Answer 4

我寫了一些我自己的函數來返回一個隨機記錄，然後將它們與此處提供的其他解決方案一起計時。我的兩個人都擊敗了哈金斯方法，但他們都不能觸及@ ray023（稍做修改用於基準測試）解決方案。 @ ray023的解決方案也可以說是最簡單的。拿那個蘇珊哈金斯！

這是代碼。您可以複製它並粘貼到標準模塊中以測試您的數據。你只需要在TimeThem模塊頂部改變三個常量：

Private Declare Function GetTickCount Lib "kernel32"() As Long 

Sub TimeThem() 
Const Loops As Integer = 10 
Const TblName As String = "Batches" 
Const FldName As String = "BatchName" 
Const IndexFld As String = "BatchID" 
Dim i As Integer, s As Long, dummy As Variant 

    s = GetTickCount 
    For i = 1 To Loops 
     dummy = HarkinsRandom(TblName, FldName) 
    Next i 
    Debug.Print "Harkins:"; GetTickCount - s 

    s = GetTickCount 
    For i = 1 To Loops 
     dummy = RandomRecord(TblName, FldName) 
    Next i 
    Debug.Print "RandomRecord:"; GetTickCount - s 

    s = GetTickCount 
    For i = 1 To Loops 
     dummy = RandomRecordWithIndex(TblName, FldName, IndexFld) 
    Next i 
    Debug.Print "WithIndex:"; GetTickCount - s 

    s = GetTickCount 
    For i = 1 To Loops 
     dummy = CallRandomRecord(TblName, FldName) 
    Next i 
    Debug.Print "CallRandom:"; GetTickCount - s 


End Sub 

Function HarkinsRandom(TblName As String, FldName As String) 
    Dim rs As DAO.Recordset 
    Set rs = CurrentDb.OpenRecordset(" SELECT TOP 1 " & FldName & _ 
            " FROM " & TblName & _ 
            " ORDER BY GetRandomValue(" & FldName & ")", _ 
            dbOpenForwardOnly) 
    HarkinsRandom = rs(0) 
End Function 

Public Function GetRandomValue(fld As Variant) 
    Randomize 
    GetRandomValue = Rnd(1) 
End Function 

Function RandomRecord(TblName As String, FldName As String) 
Dim NumRecs As Long, RecNum As Long 
Dim SQL As String, SubSQL As String, rs As DAO.Recordset 
Dim IndexFld As String 

    Randomize 
    NumRecs = CurrentDb.OpenRecordset("SELECT Count(*) FROM " & TblName, dbOpenForwardOnly)(0) 
    RecNum = Int(Rnd() * NumRecs + 1) 
    SQL = " SELECT TOP 1 " & FldName & _ 
      " FROM (" & _ 
      " SELECT TOP " & RecNum & " " & FldName & " " & _ 
      " FROM " & TblName & _ 
      " ORDER BY " & FldName & ")" & _ 
      " ORDER BY " & FldName & " DESC" 
    Set rs = CurrentDb.OpenRecordset(SQL, dbOpenForwardOnly) 
    RandomRecord = rs(0) 
End Function 

Function RandomRecordWithIndex(TblName As String, FldName As String, _ 
           Optional IndexedFieldName As String) 
Dim NumRecs As Long, RecNum As Long 
Dim SQL As String, SubSQL As String, rs As DAO.Recordset 
Dim IndexFld As String 

    Randomize 
    NumRecs = CurrentDb.OpenRecordset("SELECT Count(*) FROM " & TblName, dbOpenForwardOnly)(0) 
    RecNum = Int(Rnd() * NumRecs + 1) 
    If Len(IndexedFieldName) = 0 Or IndexedFieldName = FldName Then 
     SQL = " SELECT TOP 1 " & FldName & _ 
       " FROM (" & _ 
       " SELECT TOP " & RecNum & " " & FldName & " " & _ 
       " FROM " & TblName & _ 
       " ORDER BY " & FldName & ")" & _ 
       " ORDER BY " & FldName & " DESC" 
    Else 
     SQL = " SELECT TOP 1 " & FldName & _ 
       " FROM (" & _ 
       " SELECT TOP " & RecNum & " " & FldName & ", " & IndexedFieldName & _ 
       " FROM " & TblName & _ 
       " ORDER BY " & IndexedFieldName & ")" & _ 
       " ORDER BY " & IndexedFieldName & " DESC" 

    End If 
    Set rs = CurrentDb.OpenRecordset(SQL, dbOpenForwardOnly) 
    RandomRecordWithIndex = rs(0) 
End Function 

Function CallRandomRecord(TblName As String, FldName As String) 
    Dim rs As DAO.Recordset 
    Dim recordCount As Long 
    Dim RandomRecord As Long 

    Set rs = CurrentDb.OpenRecordset("SELECT " & FldName & " FROM " & TblName) 
    rs.MoveLast 'To get the count 
    rs.MoveFirst 
    recordCount = rs.recordCount - 1 
    RandomRecord = CLng((recordCount) * Rnd) 

    rs.Move RandomRecord 

    CallRandomRecord = rs(0) 
'  Debug.Print "Random Record No:" & randomRecord & " Field 1: " & rs.Fields(0) 

End Function 

這裏是運行對錶約50,000條記錄（這是一個本地連接的Jet表中的測試結果，即，它是在同一臺計算機在那裏，我跑測試上一個.mdb）：

Harkins: 4461 
RandomRecord: 2528 
WithIndex: 1918 
CallRandom: 172 

Harkins: 4150 
RandomRecord: 2278 
WithIndex: 2043 
CallRandom: 47 

CallRandom: 63 
WithIndex: 2090 
RandomRecord: 2324 
Harkins: 4197 

CallRandom: 46 
WithIndex: 1997 
RandomRecord: 2169 
Harkins: 4150 

我跑了四次前兩後反向排序來考慮潛在的高速緩存的優勢。正如你所看到的，我的兩個函數的運行速度約爲Harkins解決方案的兩倍，但@ ray023的解決方案速度最慢，速度提高了25倍以上（最快速度提高了近100倍）。

但通過一切手段，基準與您自己的數據。

Answer 5

我可能太簡單瞭解這個問題，但在我看來，如果你想檢索一個隨機圖像，那麼你所需要做的就是生成一個隨機數字，它以某種方式鍵入圖像表提供給你。如果有100個圖像以供選擇，你想從1到100

一個隨機數所以，你生成一個數字：

Round(100 * Rnd(), 0) 

...然後你用它來獲取圖像。如果圖像表具有自動編號PK，那麼您可以使用它，而且它會非常快。如果您的圖像位於子窗體中，則可以將LinkMaster設置爲文字PK值，然後爲您檢索圖像。

關於Randomize（）的主題，當我在立即窗口中調用Rnd（）時，似乎無法重複它，所以我不確定是否需要它。

但是這對我來說似乎是一個非常簡單的操作，可能不需要任何SQL或使用記錄集。如果您使用記錄集路線，我建議您打開一次並保存它，然後在每次需要時導航它，而不是在每次需要新圖像時重複打開它。但是如果我這樣做了，我會盡可能爲自己做一些簡單的事情，然後使用Autonumber PK路線獲取圖像。如果你想在SQL中執行它，那將是：

SELECT Images.ID, Images.Path 
    FROM Images 
    WHERE Images.ID = Round(100 * Rnd(), 0) 

Obvoiusly，你會將100更改爲適當的數字。如果您需要Randomize（），則用一個調用Randomize（）的函數替換直接Round(100 * Rnd(), 0)，然後返回Round(100 * Rnd(), 0)。

但也許我錯過了一些重要的細節，使得這似乎比我想象的要複雜得多。