列表，Grails中映射值

Question

我需要填充一張地圖，這樣：

• 關鍵是字符串
• 值是字符串列表

的過程是去通過具有兩個文本字段的表格中的所有記錄：「參數」和「值」。 「參數」不是唯一的，有很多重複。所以我打算做的是：

def all = MyTable.findAll() 
def mymap = [:] 

all.each { 
    // add to mymap the element "it.value" to the list that has "it.parameter" as key 
} 

任何線索？

感謝

Answer 1

有一個恕我直言有點簡單的方式通過在Groovy 1.7引入了「withDefault」這樣做：

all = [ 
    [parameter: 'foo', value: 'aaa'], 
    [parameter: 'foo', value: 'bbb'], 
    [parameter: 'bar', value: 'ccc'], 
    [parameter: 'baz', value: 'ddd'] 
] 

def myMap = [:].withDefault { [] } 
all.each { 
    myMap[it.parameter] << it.value 
} 

assert myMap.size() == 3 
assert myMap.foo == ['aaa','bbb'] 
assert myMap.bar == ['ccc'] 
assert myMap.baz == ['ddd'] 

Answer 2

可以使用Map.groupBy方法，這將集合分成地圖基於在封閉的組經由。這裏有一個完整的例子，這也要求收集，使每個參數指向剛纔值：

all = [ 
    [parameter: 'foo', value: 'aaa'], 
    [parameter: 'foo', value: 'bbb'], 
    [parameter: 'bar', value: 'ccc'], 
    [parameter: 'baz', value: 'ddd'] 
] 
tmpMap = all.groupBy{it.parameter} 
myMap = [:].putAll(tmpMap.collect{k, v -> [k, v.value] as MapEntry}) 

assert myMap == [foo: ['aaa', 'bbb'], bar: ['ccc'], baz:['ddd']]