如何在迭代時刪除散列元素？

Question

我有相當大的散列（一些10M鍵），我想從中刪除一些元素。

我通常不喜歡使用delete或splice，我最終複製了我想要的而不是刪除我不想要的東西。但是這一次，由於散列非常大，我想我想直接從它中刪除。

所以我在做這樣的事情：

foreach my $key (keys %hash) { 
if (should_be_deleted($key)) { 
    delete($hash{$key}); 
} 
} 

而且它似乎工作確定。但是..如果我想在迭代它們之前刪除一些元素呢？我將舉例說明：

foreach my $key (keys %hash) { 
if (should_be_deleted($key)) { 
    delete($hash{$key}); 
    # if $key should be deleted, so does "$key.a", "kkk.$key" and some other keys 
    # I already know to calculate. I would like to delete them now... 
} 
} 

我想一些可能的解決方案 - 比如檢查是否有鍵仍然存在，如在環或第一循環的第一步，創建密鑰的列表中刪除（並沒有實際刪除他們），然後在另一個循環中實際刪除。

您對此有何看法？

UPDATE

這似乎是雙通的辦法有一個共識。然而，從第一遍的過程中我仔細檢查已經標記爲刪除的鍵是非常低效的。這是有點遞歸的，因爲不僅我檢查了密鑰，還計算了應該刪除的其他密鑰，儘管它們已經由原始密鑰計算出來了。

也許我需要使用一些更加動態的數據結構遍歷鍵，將動態更新？

Answer 1

根據問題中的示例，您可以使用grep過濾出與您的$key令牌相匹配的密鑰。

更新

您的評論已澄清了你的需要。我的建議是確定符合您的要求的索引並更新您的相應設置@keys。這個想法是更新@keys，同時循環它，以避免不必要的迭代。

我已經實現了簡單的grep這裏可定製的功能。

sub matches { $_[0] =~ /$_[1]/ ? 1 : 0 } # Simple grep implemented here 

my @keys = keys %hash; # @keys should initially contain all keys 

while (@keys) { 

    my $key = shift @keys; 
    next unless should_be_deleted ($key); # Skip keys that are wanted 

    my @indexes_to_delete = grep { matches ($key, qr/$keys[$_]/) } 0 .. $#keys; 

    delete @hash { @keys[@indexes_to_delete] };  # Remove the unwanted keys 

    splice @keys, $_, 1 foreach @indexes_to_delete; # Removes deleted ... 
                # ... elements from @keys. 
                # Avoids needless iterations. 
} 

Answer 2

如何：

my %to_delete; 

foreach my $key (keys %hash) { 
    if (should_be_deleted($key)) { 
     $to_delete{$key}++; 
    } 
    # add some other keys the same way... 
} 

delete @hash{keys %to_delete}; 

Answer 3

我建議這樣做兩遍，因爲它更健壯。散列順序是有效的隨機數，所以不能保證你會在相關的鍵之前看到「主鍵」。例如，如果should_be_deleted()只檢測到不需要的主鍵並計算相關的主鍵，則最終可能會處理不需要的數據。兩步法避免了這個問題。

my @unwanted; 
foreach my $key (keys %hash) { 
    if (should_be_deleted($key)) { 
     push @unwanted, $key; 
     # push any related keys onto @unwanted 
    } 
} 

delete @hash{@unwanted}; 

foreach my $key (keys %hash) { 
    # do something 
} 

Answer 4

您可以通過將其值設置爲undef來標記要刪除的散列元素。這樣可以避免浪費要刪除的單獨密鑰列表上的空間，並避免對已標記爲要刪除的元素進行檢查。而它也將減少浪費使用each，而不是for，它建立開始迭代循環

像這樣

while (my ($key, $val) = each %hash) { 

    next unless defined $val and should_be_deleted($key); 

    $hash{$key}  = undef; 
    $hash{$key.'a'} = undef; 
    $hash{'kkk'.$key} = undef; 
} 

while (my ($key, $val) = each %hash) { 
    delete $hash{$key} unless defined $val; 
}