標記一個單詞的所有實例（德爾福，RichText）

Question

好吧，這是一個嘮叨的問題，我看不到一個明確的答案。 如何查找和標記單詞的所有實例？

我的意思是，我搜索一個詞（說：人）。如果這個單詞存在，我用richedit標記（使用紅色或其他顏色）該單詞的所有實例。如果我按Esc鍵，則會取消選擇。

任何想法？

代碼表示讚賞。

Answer 1

wonderer，我寫了這個代碼，我希望這將是有用的：

Procedure MarkString(RichEdit:TRichEdit;strtomark : string); 
Var 
FoundAt : integer; 
begin 
    FoundAt:=RichEdit.FindText(strtomark,0,maxInt,[stWholeWord]); 
    while FoundAt <> -1 do 
    begin 
      RichEdit.SelStart := FoundAt; 
      RichEdit.SelLength := Length(strtomark); 
      RichEdit.SelAttributes.Style := [fsBold]; 
      RichEdit.SelAttributes.Color := clRed; 
      RichEdit.SelText :=strtomark; 
      FoundAt:=RichEdit.FindText(strtomark,FoundAt + length(strtomark),maxInt,[stWholeWord]); 
    end; 
end; 


Procedure UnMarkString(RichEdit:TRichEdit;strtomark : string); 
Var 
FoundAt : integer; 
begin 
    FoundAt:=RichEdit.FindText(strtomark,0,maxInt,[stWholeWord]); 
    while FoundAt <> -1 do 
    begin 
      RichEdit.SelStart := FoundAt; 
      RichEdit.SelLength := Length(strtomark); 
      RichEdit.SelAttributes.Style := []; 
      RichEdit.SelAttributes.Color := clBlack; 
      RichEdit.SelText :=strtomark; 
      FoundAt:=RichEdit.FindText(strtomark,FoundAt + length(strtomark),maxInt,[stWholeWord]); 
    end; 
end; 


MarkString(RichEdit1,'delphi'); //To Mark a string 

UnMarkString(RichEdit1,'delphi'); //To UnMark a string 

再見。

Answer 2

以下代碼將在豐富的編輯控件中搜索給定單詞（區分大小寫）的所有匹配項，將字體顏色更改爲紅色，並最終恢復控件的原始選擇（全部儘可能少的閃爍）希望）：

procedure TForm1.FindWord(const AWord: string; AOptions: TSearchTypes); 
var 
    OrigSelStart, OrigSelLen: integer; 
    Start, Found: integer; 
begin 
    if AWord = '' then 
    exit; 

    OrigSelStart := RichEdit1.SelStart; 
    OrigSelLen := RichEdit1.SelLength; 

    RichEdit1.Perform(WM_SETREDRAW, 0, 0); 
    try 
    Start := 0; 
    Found := RichEdit1.FindText(AWord, Start, MaxInt, AOptions); 
    while Found <> -1 do begin 
     RichEdit1.SelStart := Found; 
     RichEdit1.SelLength := Length(AWord); 
     // TODO: save start of search match and original font colour 
     RichEdit1.SelAttributes.Color := clRed; 
     Start := Found + Length(AWord); 
     Found := RichEdit1.FindText(AWord, Start, MaxInt, AOptions); 
    end; 
    finally 
    RichEdit1.SelStart := OrigSelStart; 
    RichEdit1.SelLength := OrigSelLen; 
    RichEdit1.Perform(WM_SETREDRAW, 1, 0); 
    RichEdit1.Repaint; 
    end; 
end; 

現在你只需要到比賽保存加上原有的文本屬性的列表，並使用這些信息在此列表中恢復所有對Esc新聞界的變化。然而，如果你認爲這些匹配可能包含不同的字體樣式，顏色等，這可能會非常難以正確執行。因此，我沒有提供任何代碼來保存格式，這取決於您的要求。

哦，確保在文本可以再次更改之前刪除突出顯示的匹配項，否則您將無法正確恢復原始文本格式。