正則表達式 - Sed

Question

我將如何替換四和五後面的逗號|但不是那些跟隨一個和兩個？

\"One,Two, Three\" Four, Five, Six 

sed s'/,/|/'g 

我將不勝感激一個答案，可以適用於任何逗號內的轉義引號，而不僅僅是這個例子。

另一個例子是：

Mr ,Joe,Lish,,\"Acme, Inc.\",\"9599 Park Avenue, Suite 301\",Manhattan,NY,10022,\"\"\"6 A MAILING LIST MMBR GENERAL\"\"\" 

Answer 1

有前瞻和回顧後運營商正則表達式。例如，Javascript調用

bodyText = bodyText.replace（/ Aa（？= A）/ g，'AaB'）;

如果後面跟着另一個「A」，則會將「Aa」替換爲「AaB」，而將「AaBA」替換爲您。它不會與「AaB」相匹配，因爲「Aa」之後沒有其他「A」。這是一個向前看的電話。

我相信lookbehind的語法是？ < =。因此，如果這些操作符由您使用的軟件包支持，那麼您可以使用它們匹配「，」前面加「四」或「五」，只替換「，」。

Answer 2

我想出了這樣一個：

echo '\"One,Two, Three\" Four, Five, Six' | sed 's/\(\("[^"]*"\)\?[^",]\+\),/\1 |/g' 

其中假定線就像使用sed

[ ["someting"] word, ]* ["someting"] word 

Answer 3

方式一：

內容的 script.sed

：

## Substitute '\"' with '\n'. 
s/\\\"/\n/g 

## If there is an odd number of '\"' or the string doesn't end with '\"' I 
## will append some at the end. There is no danger, but it will be used to 
## avoid an infinite loop. 
## 1.- Save content to 'hold space'. 
## 2.- Remove all characters except '\n'. 
## 3.- Remove one of them because next command will add another one. 
## 4.- Put content in 'pattern space' to begin working with it. 
## So, if in original string there were 3 '\"', now there will be 6. ¡Fine! 
h 
s/[^\n]//g 
s/\n// 
H 
g 

## Label 'a'. 
:a 

## Save content to 'hold space'. 
h 

## Remove from first '\n' until end of line. 
s/\(\n\).*$/\1/ 

## Substitute all commas with pipes. 
s/,/|/g 

## Delete first newline. 
s/\n// 

## Append content to print as final output to 'hold space'. 
H 

## Recover rest of line from 'hold space'. 
g 

## Remove content modified just before. 
s/[^\n]*// 

## Save content to 'hold space'. 
h 

## Get first content between '\n'. 
s/\(\n[^\n]*\n\).*$/\1/ 
s/\n\{2,\}// 

## Susbtitute '\n' with original '\"'. 
s/\n/\\"/g 

## Append content to print as final output to 'hold space'. 
H 

## Recover rest of line from 'hold space'. 
g 

## Remove content printed just before. 
s/\n[^\n]*\n// 

/^\n/ { 
    s/\n//g 
    p 
    b 
} 

ba 

內容infile：

\"One,Two, Three\" Four, Five, Six 
One \"Two\", Three, Four, Five 
One \"Two, Three, Four, Five\" 
One \"Two\" Three, Four \"Five, Six\" 

運行它想：

sed -nf script.sed infile 

結果如下：

\"One,Two, Three\" Four| Five| Six 
One \"Two\"| Three| Four| Five 
One \"Two, Three, Four, Five\" 
One \"Two\" Three| Four \"Five, Six\" 

Answer 4

這可能會爲你工作：

sed 's/^/\n/;:a;s/\n\("[^"]*"\|[^,]\)/\1\n/;ta;s/\n,/|\n/;ta;s/.$//' file 

Expla國家：

• 預先在模式空間換行。 s/^/\n/
• 製作標籤:a
• 將換行符移動到引號之間的字符串或不是逗號的字符之間。 s/\n\("[^"]*"\|[^,]\)/\1\n/
• 如果替換是標籤的成功循環。 ta
• 用\n,代替|\n。s/\n,/|\n/
• 如果替換是標籤的成功循環。 ta
• 如果不進行替換，則全部刪除換行符。 s/.$//

編輯：

其實任何字符的獨特字符或組合可以用來代替\n：

echo 'Mr ,Joe,Lish,,\"Acme, Inc.\",\"9599 Park Avenue, Suite 301\",Manhattan,NY,10022,\"\"\"6 A MAILING LIST MMBR GENERAL\"\"\"' | 
sed 's/^/@@@/;:a;s/@@@\("[^"]*"\|[^,]\)/\1@@@/;ta;s/@@@,/|@@@/;ta;s/@@@$//' 
Mr |Joe|Lish||\"Acme, Inc.\"|\"9599 Park Avenue, Suite 301\"|Manhattan|NY|10022|\"\"\"6 A MAILING LIST MMBR GENERAL\"\"\"