更改XML文件內的文件擴展名

Question

這是一個棘手的問題。我有一個contents.xml文件引用其他文件的主機。這些其他文件使用.xml，並已被修改爲.dita，我的問題是我如何重命名所有的.xml文件擴展名爲.dita？文件路徑在樹中是不同的級別，並且前面的子文件夾數量不一致。
例子：

<article 
    xmlns:xi="http://www.w3.org/2001/XInclude"> 

    <title>Definition</title> 
    <xi:include href="./introduction.xml"/> 
    <section xml:id="viewComponents"><title>View Components</title> 
     <xi:include href="./components/page.xml"/> 
     <xi:include href="./views/sheet.xml"/> 
     <xi:include href="./folder/xsubfolders/plaque.xml"/> 
    </section> 
</article> 

要：

<article 
    xmlns:xi="http://www.w3.org/2001/XInclude"> 

    <title>Definition</title> 
    <xi:include href="./introduction.dita"/> 
    <section xml:id="viewComponents"><title>View Components</title> 
     <xi:include href="./components/page.dita"/> 
     <xi:include href="./views/sheet.dita"/> 
     <xi:include href="./folder/xsubfolders/plaque.dita"/> 
    </section> 
</article> 

Answer 1

這種轉變：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:xi="http://www.w3.org/2001/XInclude"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
    <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match= 
    "xi:include/@href[substring(., string-length()-3)='.xml']"> 
    <xsl:attribute name="href"> 
    <xsl:value-of select="concat(substring(.,1, string-length()-3),'dita')"/> 
    </xsl:attribute> 
</xsl:template> 
</xsl:stylesheet> 

時所提供的XML文檔應用：

<article 
    xmlns:xi="http://www.w3.org/2001/XInclude"> 

    <title>Definition</title> 
    <xi:include href="./introduction.xml"/> 
    <section xml:id="viewComponents"><title>View Components</title> 
     <xi:include href="./components/page.xml"/> 
     <xi:include href="./views/sheet.xml"/> 
     <xi:include href="./folder/xsubfolders/plaque.xml"/> 
    </section> 
</article> 

產生想要的，正確的結果：

<article xmlns:xi="http://www.w3.org/2001/XInclude"> 
    <title>Definition</title> 
    <xi:include href="./introduction.dita"></xi:include> 
    <section xml:id="viewComponents"> 
     <title>View Components</title> 
     <xi:include href="./components/page.dita"></xi:include> 
     <xi:include href="./views/sheet.dita"></xi:include> 
     <xi:include href="./folder/xsubfolders/plaque.dita"></xi:include> 
    </section> 
</article> 

Answer 2

你可以用遞歸做到這一點：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 


    <xsl:template match="@*"> 
     <xsl:choose> 
      <xsl:when test="substring(string(.), string-length(string(.)) - 3) = '.xml'"> 
       <xsl:attribute name="{name()}"> 
        <xsl:value-of select="concat(substring(string(.), 1, string-length(string(.)) - 4), '.dita')"/> 
       </xsl:attribute> 
      </xsl:when> 
      <xsl:otherwise> 
       <xsl:attribute name="{name()}"><xsl:value-of select="string(.)"/></xsl:attribute> 
      </xsl:otherwise> 
     </xsl:choose> 
    </xsl:template> 

    <xsl:template match="node()"> 
     <xsl:copy><xsl:apply-templates select="./node()|./@*"/></xsl:copy> 
    </xsl:template> 
</xsl:stylesheet> 

底部將模板複製所有直接輸入到輸出除了被拾取的屬性外上面的模板和文本轉換應用在這裏。