有沒有一種簡單的方法來設置本地，自包含的Web服務器進行Perl測試？

Question

我正在構建一個perl應用程序來存檔簡單的網頁（即沒有涉及查詢字符串的靜態頁面）。我想編寫測試來驗證將訪問遠程文件的模塊的功能。爲了使測試能夠自我依賴，我正在尋找一個簡單的，自包含的測試腳本可以在本地使用的Web服務器。

下面是一個例子，概述了我想要做的事情。我已經把它刪減到最低限度具有以下目錄結構： 「./MirrorPage.pm 」的

./MirrorPage.pm 
./t/001_get_url.t 
./t/test-docroot/test-1.json 

內容：的「 ./t/001_get_url.t」

package MirrorPage; 

use Moose; 
use LWP::Simple; 
use namespace::autoclean; 

sub get_url { 

    my ($self, $url_to_get) = @_; 

    ### grab the contents of the url 
    my $url_data = get($url_to_get); 

    ### return the contents. 
    return $url_data; 

} 

__PACKAGE__->meta->make_immutable; 

1; 

內容：

#!/usr/bin/perl 

use Modern::Perl; 
use Test::More; 
use MirrorPage; 

    ### Start test www server on port 8123 here ### 

my $t = new_ok('MirrorPage', undef, 'Create MirrorPage'); 

is(
    $t->get_url("http://localhost:8123/test-1.json"), 
    '{ testkey: "testvalue" }', 
    "Verify the data." 
); 

    ### Kill test www server here ### 

done_testing(); 

的 「./t/test-docroot/test-1.json」 內容：

{ testkey: "testvalue" } 

目標是在「./t/001_get_url.t」中相應的註釋位置啓動並終止一個自包含的Web服務器。 Web服務器需要將「./t/test-docroot」目錄的內容作爲其文檔根目錄。

鑑於以上所有內容：什麼是最佳/最簡單的方式來設置一個自包含的Web服務器提供靜態文件在Perl中測試？

Answer 1

LWP可以獲取文件，因此您可以將重寫爲$url_to_get至file://...。

Answer 2

雖然它是特定操作系統，但我相信Apache是​​你的答案。

Answer 3

我會嘲笑你附近.T文件頂部的HTTP調用（如果你只是想測試MirrorPage.pm）：

my $mock = new Test::MockObject(); 
$mock->fake_module('LWP::Simple', get => sub { return '{ testkey: "testvalue" }' }); 

Answer 4

也許：

在頂部，叉並使用HTTP::Server::Simple::Static做一個簡單的靜態文件服務器，然後在底部終止子進程。

Answer 5

這是我想出的使用Net::HTTPServer。基於「It’s OK to Ask and Answer Your Own Questions」的想法，我在這裏發表評論/考慮。我所做的是：

首先，在「./t/TestServer.pm」創建一個新模塊。這個文件的內容是：

package TestServer; 

use Moose; 
use Net::HTTPServer; 
use namespace::autoclean; 

has 'server' => (
    is => "rw", 
    isa => "Net::HTTPServer", 
    default => sub { 
     Net::HTTPServer->new (
      port => 8123, 
      docroot => "t/test-docroot" 
     ) 
    }, 
); 


sub BUILD { 

    my $self = shift; 

    ### Spin up the server. 
    $self->server->Start(); 
    $self->server->Process(); 

} 

### Close up the Moose package. 
__PACKAGE__->meta->make_immutable; 

1; 

然後，更新測試「./t/001_get_url.t」文件通過叉使用它：

#!/usr/bin/perl 

use Modern::Perl; 
use Test::More; 
use MirrorPage; 

### Fork for the server 
my $pid = fork(); 

### Parent process. Holds the tests. 
if($pid) { 

    ### Make sure the server has a moment to startup 
    sleep(2); 

    my $t = new_ok('MirrorPage', undef, 'Create MirrorPage'); 

    is(
     $t->get_url("http://localhost:8123/test-1.json"), 
     '{ testkey: "testvalue" }', 
     "Verify the data." 
    ); 
} 

### Child process. Holds the server. 
elsif(defined($pid)) { 

    use lib "t/"; 
    use TestServer; 

    my $svr = TestServer->new(); 

    exit; # Should never get here. 

} 

### Error out if necessary. 
else { 
    die "Can not fork child process."; 
} 


### Kill the server fork. 
kill 1, $pid; 

done_testing(); 

這是爲我工作很好。

Answer 6

我強烈推薦Mojolicious作爲爲客戶端生成測試服務器的好方法。由於Mojolicious只是將URL映射到子例程調用中，因此很容易對服務器的功能進行非常好的控制，因此您可以輕鬆測試諸如「服務器返回錯誤響應/錯誤內容/超時「。由於設置和拆除服務器非常簡單，使用fork（）可以使測試和服務器設置在同一個測試文件中。