從動態變量填充節點

Question

我想要在輸出文檔（輸入可以是任何東西）內的根標籤下的節點a中獲得值「a」。我知道如果我做

<xsl:value-of select="$item1"/> 

我會得到所需的值。但是我想使用類似

<xsl:value-of select="concat('$item','1')"/> 

的原因是因爲我可以有許多變量創建動態，並在變量的末尾數被遞增。所以我可以有item1，item2，item3等。我在這裏展示了一個示例，這就是爲什麼我在select的值中使用硬編碼值'1'。這可能在xslt1.0中嗎？

這是我的XSLT，任何輸入XML可以用來

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl" 
> 
    <xsl:output method="xml" indent="yes"/> 

    <xsl:template match="/"> 
     <xsl:variable name="item1" select="'a'" /> 
     <Root> 
     <a> 
      <xsl:value-of select="concat('$item','1')"/> 
     </a> 
     </Root> 
    </xsl:template> 
</xsl:stylesheet> 

Answer 1

PHP等變量變量是不可能在XSLT 1.0/1.0的XPath。

通過使用exslt -extension的node-set()函數，可以構建一個像數組一樣工作的節點集。

<?xml version='1.0' encoding='UTF-8'?> 
<xsl:stylesheet version='1.0' 
       xmlns:xsl='http://www.w3.org/1999/XSL/Transform' 
       xmlns:exsl='http://exslt.org/common' 
       xmlns:msxsl='urn:schemas-microsoft-com:xslt' 
       exclude-result-prefixes='msxsl exsl'> 

<xsl:template match='/'> 
    <!-- result tree fragment --> 
    <xsl:variable name='_it'> 
     <em>a</em> 
     <em>b</em> 
     <em>c</em> 
     <em>d</em> 
    </xsl:variable> 
    <!-- create a node-set from the result tree fragment --> 
    <xsl:variable name='it' select='exsl:node-set($_it)'/> 
    <Root> 
     <a> 
      <!-- 
       this is a normal xpath with the variable '$it' and a node 'em' 
       the number in brackets is the index starting with 1 
      --> 
      <xsl:value-of select='$it/em[1]'/> <!-- a --> 
      <xsl:value-of select='$it/em[2]'/> <!-- b --> 
     </a> 
    </Root> 
</xsl:template> 

<!-- MS doesn't provide exslt --> 
<msxsl:script language='JScript' implements-prefix='exsl'> 
    this['node-set'] = function (x) { 
     return x; 
    } 
</msxsl:script> 

</xsl:stylesheet>