替換使用正則表達式

Question

在文本文件中的所有文本我有一個文本文件，下面的文本

 
161624.406 : Send:[sometext1] 
161624.437 : Send:[sometext2] 
161624.468 : Send:[sometext3] 
161624.499 : Send:[sometext4] 
161624.531 : Send:[sometext5] 

我想只保留在該文件中sometext一部分。所需的輸出是

 
sometext1 
sometext2 
sometext3 
sometext4 
sometext5 

我正在使用Excel的VBA

Public Sub testa() 
    a = "C:\Users\pankaj.jaju\Desktop\test.log" 

    Set objFSO = CreateObject("Scripting.FileSystemObject") 
    Set objTxtFile = objFSO.OpenTextFile(a, 1) 
    strText = objTxtFile.ReadAll 
    objTxtFile.Close 
    Set objTxtFile = Nothing 


    Set objRegEx = CreateObject("VBScript.RegExp") 
    With objRegEx 
     .Global = True 
     .MultiLine = True 
     .Pattern = "\[([^]]+)\]" 
     Set objRegMC = .Execute(strText) 
     b = objRegMC(0).SubMatches(0) 
    End With 
    Set objRegEx = Nothing 

    Debug.Print b 
End Sub 

下面的代碼的問題是輸出顯示爲僅sometext1。我如何在文本文件中輸入ReplaceAll並僅用所需的文本保存文件。

Answer 1

的regex.Replace方法應該做的伎倆。

獨立的模式成組這樣的："(.*?)(\[)([^]]+)(\])(.*?)"

現在你可以更換這是在這種情況下，三場小組匹配組的輸入字符串：objRegEx.Replace(strText, "$3")

---

這裏是一個helpful link到Excel中正則表達式的不同示例。

Answer 2

正則表達式顯然只抓取字符串的第一個匹配。我不夠精通正則表達式來拿出一個正則表達式唯一的解決辦法，考慮到\n

簡單的解決方法是使用objTxtFile.ReadLine，而不是ReadAll

通過一個閱讀一個每個字符串，正則表達式的應用並獲得輸出。

Public Sub testa() 
    a = "C:\Users\pankaj.jaju\Desktop\test.log" 

    Set objFSO = CreateObject("Scripting.FileSystemObject") 
    Set objTxtFile = objFSO.OpenTextFile(a, 1) 

    Do Until (objTxtFile.AtEndOfStream) 'Loop till EOF 
     strText = objTxtFile.ReadLine 'Single line read instead of ReadAll 

     Set objRegex = CreateObject("VBScript.RegExp") 
     With objRegex 
      .Global = True 
      .MultiLine = True 
      .Pattern = "\[([^]]+)\]" 
      Set objRegMC = .Execute(strText) 
      b = objRegMC(0).SubMatches(0) 
     End With 
     Set objRegex = Nothing 

     Debug.Print b 'replace this with the code to output the string where you want etc 
    Loop 
    objTxtFile.Close 
End Sub 

Answer 3

OK ...找到一種方法來做到這一點（由於MSDN ...有時文檔是有用的:-)）。分享答案

Public Sub testa() 
    a = "C:\Users\pankaj.jaju\Desktop\test.log" 

    Set objFSO = CreateObject("Scripting.FileSystemObject") 
    Set objTxtFile = objFSO.OpenTextFile(a, 1) 
    strText = objTxtFile.ReadAll 
    objTxtFile.Close 
    Set objTxtFile = Nothing 

    b = "" 
    Set objRegEx = CreateObject("VBScript.RegExp") 
    With objRegEx 
     .Global = True 
     .MultiLine = True 
     .Pattern = "\[([^]]+)\]" 
     Set objMatches = .Execute(strText) 

     For Each Match In objMatches 
      For Each SubMatch In Match.SubMatches 
       b = b & SubMatch & vbCrLf 
      Next SubMatch 
     Next Match 

    End With 
    Set objRegEx = Nothing 

    Set objTxtFile = objFSO.OpenTextFile(a, 2) 
    objTxtFile.Write b 
    objTxtFile.Close 
    Set objTxtFile = Nothing 
End Sub 

編輯 - 基於@ PortlandRunner的建議

Public Sub testa() 
a = "C:\Users\pankaj.jaju\Desktop\test.log" 

Set objFSO = CreateObject("Scripting.FileSystemObject") 
Set objTxtFile = objFSO.OpenTextFile(a, 1) 
strText = objTxtFile.ReadAll 
objTxtFile.Close 
Set objTxtFile = Nothing 

b = "" 
Set objRegEx = CreateObject("VBScript.RegExp") 
With objRegEx 
    .Global = True 
    .MultiLine = True 
    .Pattern = "(.*?)(\[)([^]]+)(\])(.*?)" 
    b = objRegEx.Replace(strText, "$3") 
End With 
Set objRegEx = Nothing 

Set objTxtFile = objFSO.OpenTextFile(a, 2) 
objTxtFile.Write b 
objTxtFile.Close 
Set objTxtFile = Nothing 
End Sub 

Answer 4

我知道你已經得到了你的答案。但是對於這樣一個簡單的程序，爲什麼要使用正則表達式呢？這是一個4行腳本，可以做同樣的事情 - 是的，它已經過測試。

Dim a, text: a = "C:\testenv\test.log" 
text = split(CreateObject("Scripting.FileSystemObject").OpenTextFile(a, 1).ReadAll, vbcrlf) 
for i=0 to ubound(text) : text(i) = replace(split(text(i), "[")(1), "]", "") : next 
CreateObject("Scripting.FileSystemObject").OpenTextFile(a, 2).Write(Join(text, vbcrlf))