如何過濾表單中帶有多個組合框的Access子表單？

Question

我在窗體中有多個組合框（acct_nbr，type，team_aud）。我正在尋找一種基於每個組合框的選擇過濾子表單（作爲數據表）的方法。如果組合框未在過濾器中使用，則子窗體數據僅在另外兩個組合框上進行過濾。

這是我到目前爲止有：

Private Sub cboAccountFilter_AfterUpdate() 
    Call FilterSubform 
End Sub 

Private Sub cboTypeFilter_AfterUpdate() 
    Call FilterSubform 
End Sub 

Private Sub txtTeamAuditorFilter_AfterUpdate() 
    Call FilterSubform 
End Sub 

Private Sub FilterSubform() 
    Dim strWhere As String 

    If Nz(Me.cboAccountFilter, "") <> "" Then 
     strWhere = strWhere & "[acct_nbr] = '" & Me.cboAccountFilter & " ' AND " 
    End If 

    If Nz(Me.cboTypeFilter, "") <> "" Then 
     strWhere = strWhere & "[Type] = '" & Me.cboTypeFilter & " ' AND " 
    End If 

    If Nz(Me.txtTeamAuditorFilter, "") <> "" Then 
     strWhere = strWhere & "[team_aud] = '" & Me.txtTeamAuditorFilter & " ' AND " 
    End If 

    If strWhere <> "" Then 
     strWhere = Left(strWhere, Len(strWhere) - 5) 
     Me.fsubStatsDashPrimarySix.Form.Filter = strWhere 
     Me.fsubStatsDashPrimarySix.Form.FilterOn = True 
    Else 
     Me.fsubStatsDashPrimarySix.Form.Filter = "" 
     Me.fsubStatsDashPrimarySix.Form.FilterOn = False 
    End If 
End Sub 

當我點擊的組合框一個我沒有收到錯誤，但所有的數據被過濾掉。

Answer 1

更改您的過濾器，以這樣的：

If Nz(Me.cboAccountFilter, "") <> "" Then 
    strWhere = strWhere & "[acct_nbr] = '" & Trim(Me.cboAccountFilter) & "' AND " 
End If 

If Nz(Me.cboTypeFilter, "") <> "" Then 
    strWhere = strWhere & "[Type] = '" & Trim(Me.cboTypeFilter) & "' AND " 
End If 

If Nz(Me.txtTeamAuditorFilter, "") <> "" Then 
    strWhere = strWhere & "[team_aud] = '" & Trim(Me.txtTeamAuditorFilter) & "' AND " 
End If 

編輯：

按您的意見，我認爲這將是：

strWhere = strWhere & "[team_aud] LIKE *'" & Trim(Me.txtTeamAuditorFilter) & "'* AND " 

（我試圖離開，作爲一個評論，但由於SO的標記語言，星號被解釋爲斜體）。