在字符串中刪除SED空白字符

Question

我試圖用sed來替換字符串中的空白字符。例如，給定線：

var test = 'Some test text here.'; 

我想：

var test = 'Sometesttexthere.'; 

我嘗試使用（\x27匹配'）：

sed 's|\x27\([^\x27[:space:]]*\)[[:space:]]|\x27\1|g 

，但只是給

var test = 'Sometest text here.'; 

任何想法？

Answer 1

這是一個更復雜的sed腳本，但它沒有循環。你知道的，只是不同的緣故：

sed 'h;s/[^\x27]*\x27\(.*\)/\n\x27\1/;s/ //g;x;s/\([^\x27]*\).*/\1/;G;s/\n//g' 

這使得字符串的副本，打出一個（這將成爲下半年）的第一單引號丟棄上半年，替換所有的空格下半部分交換副本，將另一部分副本拆分，丟棄後半部分，將它們合併回去，並刪除用於拆分的新行和由G命令添加的新行。

編輯：

爲了選擇特定行進行操作，您可以使用一些選擇標準。在這裏，我指定的行必須包含一個等號和至少兩個單引號：

sed '/.*=.*\x27.*\x27.*/ {h;s/[^\x27]*\x27\(.*\)/\n\x27\1/;s/ //g;x;s/\([^\x27]*\).*/\1/;G;s/\n//g}' 

你可以使用任何正則表達式的作品最好的，包括並適當地排除了您的需求。

Answer 2

您的命令行有兩個問題：

• 首先，有一個失蹤\[^後。

• 其次，即使使用g修飾符，也只會刪除第一個空格。爲什麼？因爲該修飾符導致在同一行內替換連續匹配。它不是而是從頭開始重新掃描整行。但這是必需的，因爲你的匹配是錨定在字符串文字的最初'。

來解決這個問題最顯而易見的方法是使用一個環，由一個條件跳轉實現（跳轉與tLabel到:Label; t跳轉如果因爲具有t上次測試匹配的至少一個s）。

這是最簡單的一個sed腳本（和你沒有逃跑的'），像這樣：

:a 
s|'\([^'[:space:]]*\)[[:space:]]|'\1| 
ta 

但是這是可以做到一個命令提示符。確切的語法可能取決於您的sed的香味，適合礦井（在Windows超級SED）被調用，像這樣：

sed -e ":a" -e "s|\x27\([^\x27[:space:]]*\)[[:space:]]|\x27\1|;ta" 

您需要兩個單獨的腳本表情，因爲標籤:a上延伸直至表達式結束。