用條件替換子字符串

Question

我正在嘗試在列A中使用字符串搜索Excel文件，如果通過了幾個條件，則替換字符串的一部分。

按道理：if NAME and CODE(A) or CODE(B) exist in string then replace NAME

例子：NAME = child1in CODE(A) = csus CODE(B) = mfus

注：有一些需要更換，但代碼相同 TIA幾個名字！

前： child1in， 「DV」， 「」， 「個CSU」， 「非洲虛擬大學」， 「06212017」， 「06212017」， 「」， 「1」， 「」， 「」，」 CAU的」， 「$現金」， 「」， 「」， 「」， 「」， 「598.5」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」 ， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「7667079」， 「」， 「48」， 「」 「」， 「N」， 「Y」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」

後：
child1， 「DV」， 「」， 「個CSU」， 「AVU」， 「06212017」， 「06212017」， 「」， 「1」， 「」， 「」，「諸CAU 」， 「$現金」， 「」， 「」， 「」， 「」， 「598.5」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「7667079」， 「」， 「48」， 「」， 「」， 「N」， 「Y」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」， 「」，」 「

這裏是我的代碼：

---

`Sub replacement_TEST() 

Dim rows As Integer 
Dim acct1 As String 
Dim eqcode As String 

rows = ActiveSheet.UsedRange.rows.Count 

For i = 1 To rows 

acct1 = ActiveSheet.Cells(i, 1).value 
eqcode = ActiveSheet.Cells(i, 4).value 

If acct1 = "child1in" And (eqcode = "csus" Or eqcode = "mfus") Then 
          acct1 = Replace(acct1, "child1in", "child1") 
ElseIf acct1 = "wstre2in" And (eqcode = "csus" Or eqcode = "mfus") Then 
          acct1 = Replace(acct1, "wstre2in", "wstre2lv") 
ElseIf acct1 = "wstrebin" And (eqcode = "csus" Or eqcode = "mfus") Then 
          acct1 = Replace(acct1, "wstrebin", "wstrebal") 
ElseIf acct1 = "lrcfbag" And (eqcode = "csus" Or eqcode = "mfus") Then 
          acct1 = Replace(acct1, "lrcfbag", "lrcfbal") 
ElseIf acct1 = "wstpsbst" And (eqcode = "csus" Or eqcode = "mfus") Then 
          acct1 = Replace(acct1, "wstpsbst", "wstpsbal") 

       End If 

        ActiveSheet.Cells(i, 1).value = acct1 

     Next 

End Sub 

Answer 1

像這樣的東西應該工作。如果將查找/替換對放在工作表上，並在VLOOKUP中使用它，則可以更輕鬆地進行管理。

Sub replacement_TEST() 

    Dim rows As Long, i As Long, n As Long 
    Dim acct1 As String 
    Dim eqcode As String 
    Dim sht As Worksheet, arrFind, arrRepl, m 

    Set sht = ActiveSheet 
    rows = sht.UsedRange.rows.Count 

    'arrays of matching find/replace values 
    arrFind = Array("child1in", "wstre2in", "wstrebin", "lrcfbag", "wstpsbst") 
    arrRepl = Array("child1", "wstre2lv", "wstrebal", "lrcfbal", "wstpsbal") 

    For i = 1 To rows 
     acct1 = sht.Cells(i, 1).Value 
     eqcode = sht.Cells(i, 4).Value 

     If eqcode = "csus" Or eqcode = "mfus" Then 
      m = Application.Match(acct1, arrFind, 0) '<< any match ? 
      If Not IsError(m) Then 
       sht.Cells(i, 1).Value = arrRepl(m - 1) 'm is 1-based... 
      End If 
     End If 
    Next 
End Sub 

Answer 2

不太清楚這是你要找的東西，但它肯定是一個起點。根據需要修改它以適應您的需求。

Sub replacement_TEST() 

    Dim r As Range, c As Range, values As Variant 
    Set r = Range(Cells(1, 1), Cells(ActiveSheet.UsedRange.Rows.Count, 1)) 

    For Each c In r 
     'Split comma separated values 
     values = Split(c.Value, ",") 

     'According to the screenshot provided, the index of "eqcode" is 3 
     'and the "acct1" is 0 
     If values(3) = "csus" Or values(3) = "mfus" Then 
      Select Case values(0) 
       Case "child1in": 
        c.Value = Replace(c.Value, values(0), "child1") 

       Case "wstre2in": 
        c.Value = Replace(c.Value, values(0), "wstre2lv") 

       Case "wstrebin": 
        c.Value = Replace(c.Value, values(0), "wstrebal") 

       Case "lrcfbag": 
        c.Value = Replace(c.Value, values(0), "lrcfbal") 

       Case "wstpsbst": 
        c.Value = Replace(c.Value, values(0), "wstpsbal") 

       Case Else: 
        'do nothing 
      End Select 
     End If 
    Next c 
End Sub