ORACLE FUNCTION testcase

Question

我想創建一個返回BOOLEAN的函數。 該函數將檢查值是否存在（典型驗證，如果一個部門已經存在）。

我實現了NO_DATA_FOUND異常，我也想添加WHEN OTHERS;但我沒有考慮任何測試用例。

下面是函數的代碼：

FUNCTION fnc_department_exists(p_dept_name hr.departments.department_name%TYPE) RETURN BOOLEAN IS 
    v_dummy PLS_INTEGER; 
BEGIN 
    -- Verifica existenta unui anumit departament 
    pkg_logging.prc_log('HR', 'VERIFIC', 'Verifica daca exista departamentul "' || p_dept_name || '"'); 
    SELECT 1 
    INTO v_dummy 
    FROM hr.departments 
    WHERE UPPER(department_name) = UPPER(p_dept_name); 

    pkg_logging.prc_log('HR', 'VERIFIC', 'Departamentul "' || p_dept_name || '" exista'); 

    RETURN TRUE; 
EXCEPTION 
    WHEN NO_DATA_FOUND THEN 
     pkg_logging.prc_log('HR', 'VERIFIC', 'Departamentul "' || p_dept_name || '" nu exista'); 
     RETURN FALSE; 
    WHEN OTHERS THEN 
     pkg_logging.prc_log('HR', 'VERIFIC', 'A aparut o alta eroare: ' || SQLCODE || ' - ' || SQLERRM); 
     RETURN FALSE; 
END fnc_department_exists; 

有人能提出一個測試用例WHEN OTHERS分支，好嗎？

謝謝

Answer 1

如果您有一個名爲例如'PAYROLL'，添加另一個名爲'Payroll'和另一個名爲'payroll'。這將導致SELECT失敗並出現ORA-01422（TOO_MANY_ROWS）異常。

我建議當你的代碼進入WHEN OTHERS塊時，你應該重新提升異常而不是吃掉它並返回false。因此：

WHEN OTHERS THEN 
    pkg_logging.prc_log('HR', 'VERIFIC', 'A aparut o alta eroare: ' || 
         SQLCODE || ' - ' || SQLERRM); 
    RAISE; 

祝你好運。