使用一個NSIS安裝程序可以在32位操作系統上安裝32位二進制文​​件，並在64位操作系統上安裝64位二進制文​​件？

Question

我目前有兩個WIX安裝程序用於我維護的產品。一個用於32位操作系統，另一個用於64位操作系統。我不想維護兩個單獨的安裝程序，而是將它們組合成一個NSIS安裝程序，它可以「確定」操作系統的「位」，然後將適當的二進制文件複製到程序目錄中。有沒有人有過這方面的經驗，可以提供一個NSIS可以用來製作安裝程序的工作示例腳本？

Answer 1

x64.nsh有一定的輔助宏，你可以安裝到$programfiles32或$programfiles64

編輯：

Function .onInit 
StrCpy $instdir $programfiles32\MyApp 
${If} ${RunningX64} 
    StrCpy $instdir $programfiles64\MyApp 
${EndIf} 
FunctionEnd 

... 

Section 
Setoutpath $instdir 
${If} ${RunningX64} 
    File /r build\64\* 
${Else} 
    File /r build\32\* 
${EndIf} 
SectionEnd 

Answer 2

我相信，我想通了......我沒有測試過這個呢，但它應該工作...

答案是爲每組文件創建兩個「部分」。用於32位的SEC0000和用於64位文件的SEC0001。然後，

!include x64.nsh 

Function .onInit 
    #Determine the bitness of the OS and enable the correct section 
    ${if} ${RunningX64} 
    SectionSetFlags ${SEC0001} 17 
    SectionSetFlags ${SEC0000} 16 
    ${else} 
    SectionSetFlags ${SEC0001} 16 
    SectionSetFlags ${SEC0000} 17 
    ${endif} 
FunctionEnd 

我相信，同樣的邏輯，將需要在un.onInit功能也因此卸載程序知道哪些文件刪除...

Answer 3

對於使用3.0a0簡單通用的安裝程序，我發現那下面爲我工作一個小實驗：

!include x64.nsh 
Function .onInit 
    #Determine the bitness of the OS and enable the correct section 
    ${If} ${RunningX64} 
    SectionSetFlags ${SEC0000} ${SECTION_OFF} 
    SectionSetFlags ${SEC0001} ${SF_SELECTED} 
    ${Else} 
    SectionSetFlags ${SEC0001} ${SECTION_OFF} 
    SectionSetFlags ${SEC0000} ${SF_SELECTED} 
    ${EndIf} 
FunctionEnd 

我必須記住把函數引用的部分後。我的每個部分都簡單地在其各自的32位/和64位/目錄中引用同名的.exe，因此我的卸載程序不需要任何特殊處理。我沒有在32位系統上測試過它，但它確實適用於64位系統。

例子：

section "64-bit" SEC0001 
    messageBox MB_OK "64-BIT!" 
    File "C:\foo\64-bit\some-utility.exe" 
sectionEND