更改窗體大小後的窗體

Question

我有一個組合框有兩個選項，兩個選項都觸發窗體大小調整。我的想法是隱藏並顯示基於選擇的其他控件。

當我更改窗體寬度時，大小會根據需要進行更改，但窗體現在不再位於屏幕的中心。我可以在改變窗體寬度的同時來回移動窗體的XY位置嗎？

procedure TReportFrm.SpecialFilesComboBoxChange(Sender: TObject); 
begin 
    if(SpecialFilesComboBox.ItemIndex = 0) then begin 
    //No special files 
    Width := 412; 
    Height := 423; 
    ... 
    end 
    else begin 
    //Yes special files 
    Width := 893; 
    Height := 423; 
    ... 
    end; 
end; 

Answer 1

一個非常簡單的ReCenter功能可能是這樣的：

procedure TReportFrm.ReCenter; 
var 
    LRect: TRect; 
    X, Y: Integer; 
begin 
    LRect := Screen.WorkAreaRect; 
    X := LRect.Left + (LRect.Right - LRect.Left - Width) div 2; 
    Y := LRect.Top + (LRect.Bottom - LRect.Top - Height) div 2; 
    SetBounds(X, Y, Width, Height); 
end; 

procedure TReportFrm.SpecialFilesComboBoxChange(Sender: TObject); 
begin 
    if(SpecialFilesComboBox.ItemIndex = 0) then begin 
    //No special files 
    Width := 412; 
    Height := 423; 
    ... 
    end 
    else begin 
    //Yes special files 
    Width := 893; 
    Height := 423; 
    ... 
    end; 
    ReCenter; 
end; 

IT中心的窗口到屏幕的工作區，你可能希望將其中心到其他的參考，在這種情況下，它是由給你確定有意義的矩形。

Answer 2

多顯示器系統現在很常見。放置在屏幕的中心可能會將表格分散到多個顯示器上。這是不可取的。

所以我中心形式的監視器上：

R := Form.Monitor.WorkAreaRect; 
Form.Left := (R.Left+R.Right-Form.Width) div 2; 
Form.Top := (R.Top+R.Bottom-Form.Height) div 2; 

由於@bummi指出的那樣，你可以這樣寫：

Form.Position := poScreenCenter; 

這幾乎可以作爲你的願望。我將把這個表格放在屏幕上。但是，它總是選擇默認監視器。因此，使用該代碼可能會導致您的表單被移到不同的顯示器上，我認爲這絕對不可取。

而是迫使形式中心，你可以決定，而不是在所有側面擴大或縮小它：

procedure TReportFrm.SpecialFilesComboBoxChange(Sender: TObject); 
var 
    NewLeft, NewTop, NewWidth, NewHeight: Integer; 
begin 
    if(SpecialFilesComboBox.ItemIndex = 0) then begin 
    //No special files 
    NewWidth := 412; 
    NewHeight := 423; 
    ... 
    end 
    else begin 
    //Yes special files 
    NewWidth := 893; 
    NewHeight := 423; 
    ... 
    end; 

    NewLeft := Left + (Width-NewWidth) div 2; 
    NewTop := Top + (Top-NewHeight) div 2; 
    NewBoundsRect := Rect(NewLeft, NewTop, NewLeft+NewWidth, NewTop+NewHeight); 
    BoundsRect := NewBoundsRect; 
end; 

如果你想獲得真正可愛的你會調整邊界RECT從而使新大小和定位的形式沒有離開顯示器的邊緣。

procedure MakeAppearOnScreen(var Rect: TRect); 
const 
    Padding = 24; 
var 
    Monitor: HMonitor; 
    MonInfo: TMonitorInfo; 
    Excess, Width, Height: Integer; 
begin 
    Monitor := MonitorFromPoint(Point((Rect.Left+Rect.Right) div 2, (Rect.Top+Rect.Bottom) div 2), MONITOR_DEFAULTTONEAREST); 
    if Monitor=0 then begin 
    exit; 
    end; 
    MonInfo.cbSize := SizeOf(MonInfo); 
    if not GetMonitorInfo(Monitor, @MonInfo) then begin 
    exit; 
    end; 
    Width := Rect.Right-Rect.Left; 
    Height := Rect.Bottom-Rect.Top; 

    Excess := Rect.Right+Padding-MonInfo.rcWork.Right; 
    if Excess>0 then begin 
    dec(Rect.Left, Excess); 
    end; 
    Excess := Rect.Bottom+Padding-MonInfo.rcWork.Bottom; 
    if Excess>0 then begin 
    dec(Rect.Top, Excess); 
    end; 
    Excess := MonInfo.rcWork.Left+Padding-Rect.Left; 
    if Excess>0 then begin 
    inc(Rect.Left, Excess); 
    end; 
    Excess := MonInfo.rcWork.Top+Padding-Rect.Top; 
    if Excess>0 then begin 
    inc(Rect.Top, Excess); 
    end; 
    Rect.Right := Rect.Left+Width; 
    Rect.Bottom := Rect.Top+Height; 
end; 

接着前面的代碼示例將改變這樣的：

NewBoundsRect := Rect(NewLeft, NewTop, NewLeft+NewWidth, NewTop+NewHeight); 
MakeAppearOnScreen(NewBoundsRect); 
BoundsRect := NewBoundsRect;