兩個資源之間的路徑

Question

是否可以計算將兩個實例連接到SPARQL查詢的邊的數量？我想找到一條路。

Answer 1

您可以使用SPARQL的屬性路徑和聚合函數來計算唯一路徑中的邊數。例如，對於這樣的數據，它包含了我們所關心的兩個路徑（一個有兩個邊緣ç和d一起克三條邊）：

@prefix : <https://stackoverflow.com/questions/19587520/sparql-path-between-two-instance/> . 

:a :p :b . # a to c is a path of length 2 
:b :p :c . 

:d :p :e . # d to g is a path of length 3 
:e :p :f . 
:f :p :g . 

可以使用像下面這樣的查詢。注意我已經使用了特定的屬性:p，而不是一個變量。這是必需的，因爲來自SPARQL 1.1規範的9.1 Property Path Syntax不允許屬性路徑中的變量。

prefix : <https://stackoverflow.com/questions/19587520/sparql-path-between-two-instance/> 

select ?start ?end (count(?mid) as ?length) 
where { 
    values (?start ?end) { (:a :c) (:d :g) } 
    ?start :p+ ?mid . 
    ?mid :p* ?end . 
} 
group by ?start ?end 

和得到的結果是這樣的：

$ sparql --query query.rq --data data.n3 
------------------------ 
| start | end | length | 
======================== 
| :d | :g | 3  | 
| :a | :c | 2  | 
------------------------ 

這裏發生了什麼的更詳細的描述中可以找到：

• Calculate length of path between nodes?（這實際上是看路在樹）
• this answer到Finding all steps in property path（請注意，接受的答案表示您不能這樣做，但鏈接的答案說明你實際上可以）;
• 接受的答案爲Is it possible to get the position of an element in an RDF Collection in SPARQL?。

的基本理念，雖然是，如果你有從?start到?end的路徑，那麼你也有，對於一堆?mid，從?start到?mid的路徑不同的值，並從路徑?mid到?end。您可以爲?mid選擇不同值的號碼（如果您允許其中一個端點並禁止其他端點）恰好是路徑的長度。