如何使用GHC.Generics（或其他類似的框架）構造泛型函子實例？

Question

我在學習GHC仿製藥。在回顧了幾個例子之後，我想嘗試創建一個通用的Functor實例（不管GHC能爲我自動推導它們）。然而，我意識到我不知道如何使用泛型的參數化數據類型，我見過的所有例子都是*。這是可能的，如果是的話，如何？ （我對SYB等其他類似框架也很感興趣。）

Answer 1

使用GHC Generics查找大量示例函數的最佳位置是generic-deriving package。那裏有一個Functor類的通用定義。複製從Generics.Deriving.Functor（略簡體）：

class GFunctor' f where 
    gmap' :: (a -> b) -> f a -> f b 

instance GFunctor' U1 where 
    gmap' _ U1 = U1 

instance GFunctor' Par1 where 
    gmap' f (Par1 a) = Par1 (f a) 

instance GFunctor' (K1 i c) where 
    gmap' _ (K1 a) = K1 a 

instance (GFunctor f) => GFunctor' (Rec1 f) where 
    gmap' f (Rec1 a) = Rec1 (gmap f a) 

instance (GFunctor' f) => GFunctor' (M1 i c f) where 
    gmap' f (M1 a) = M1 (gmap' f a) 

instance (GFunctor' f, GFunctor' g) => GFunctor' (f :+: g) where 
    gmap' f (L1 a) = L1 (gmap' f a) 
    gmap' f (R1 a) = R1 (gmap' f a) 

instance (GFunctor' f, GFunctor' g) => GFunctor' (f :*: g) where 
    gmap' f (a :*: b) = gmap' f a :*: gmap' f b 

instance (GFunctor f, GFunctor' g) => GFunctor' (f :.: g) where 
    gmap' f (Comp1 x) = Comp1 (gmap (gmap' f) x) 


class GFunctor f where 
    gmap :: (a -> b) -> f a -> f b 
    default gmap :: (Generic1 f, GFunctor' (Rep1 f)) 
       => (a -> b) -> f a -> f b 
    gmap = gmapdefault 

gmapdefault :: (Generic1 f, GFunctor' (Rep1 f)) 
      => (a -> b) -> f a -> f b 
gmapdefault f = to1 . gmap' f . from1 

要在數據類型利用這一點，你必須得到Generic1而非Generic。 Generic1表示法的關鍵區別在於它使用編碼參數位置的Par1數據類型。

Answer 2

* -> *類型的數據類型有Generic1類。使用它的方式與*類型的數據類型大致相同，但參數的Par1也是如此。例如，我用它在我的unfoldable package中。