處理WM_SETFOCUS或WM_KILLFOCUS德爾福

Question

我需要處理WM_SETFOCUS或WM_KILLFOCUS在Delphi應用程序，我寫了這樣一個消息處理程序：

Procedure Focus(var Msg: TWMSetFocus); message WM_SetFocus; 

，但它不工作&別，叔火消息處理程序時WM_SetFocus到達後，我寫了一個應用程序消息處理程序，但對它沒有工作！

我覺得這個消息直接發送來控制，這是真的嗎？

任何人都可以幫助我做到這一點？

Answer 1

此答案假設您希望消息被窗體上的控件接收。

這些消息是非排隊的，並直接發送到控件。這就解釋了爲什麼你的兩次嘗試接收它們失敗了。

接收它們的唯一方法是通過控件的窗口過程。您有以下選項。

1. 控制子類並處理消息。這可能是最容易完成的和插入類。
2. 使用控件的WindowProc屬性替換窗口過程而不派生新類。

您可能會發現TForm.SetFocusedControl可以提供幫助。它被稱爲響應接收WM_SetFocus消息的控件，以及在其他一些情況下被調用（請參閱VCL代碼以獲取詳細信息）。

選項1：內插器

unit uWindowProc; 

interface 

uses 
    Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, 
    Dialogs, StdCtrls; 

type 
    TEdit = class(StdCtrls.TEdit) 
    protected 
    procedure WMSetFocus(var Message: TWMSetFocus); message WM_SETFOCUS; 
    end; 

    TMyForm = class(TForm) 
    Edit1: TEdit; 
    Edit2: TEdit; 
    end; 

var 
    MyForm: TMyForm; 

implementation 

{$R *.dfm} 

{ TEdit } 

procedure TEdit.WMSetFocus(var Message: TWMSetFocus); 
begin 
    inherited; 
    Beep; 
end; 

end. 

選項2：的WindowProc

unit uWindowProc; 

interface 

uses 
    Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, 
    Dialogs, StdCtrls; 

type 
    TMyForm = class(TForm) 
    Edit1: TEdit; 
    Edit2: TEdit; 
    procedure FormCreate(Sender: TObject); 
    private 
    FOriginalWindowProc: TWndMethod; 
    procedure NewWindowProc(var Message: TMessage); 
    end; 

var 
    MyForm: TMyForm; 

implementation 

{$R *.dfm} 

procedure TMyForm.FormCreate(Sender: TObject); 
begin 
    FOriginalWindowProc := Edit1.WindowProc; 
    Edit1.WindowProc := NewWindowProc; 
end; 

procedure TMyForm.NewWindowProc(var Message: TMessage); 
begin 
    if Message.Msg=WM_SETFOCUS then 
    Beep; 
    FOriginalWindowProc(Message); 
end; 

end. 

Answer 2

@Mojtaba - 的消息是否被直接發送到控制取決於什麼類型的控制它是。

正如Andrei K所建議的那樣，一條消息直接發送給TWinControl後面的控件 - 還有其他控件是TControl的後代，但它們不是TWinControls。例如，TL​​abel不是來自TWinControl，而是TPanel。

對於不是TWinControl的控件，該消息被髮送到Delphi應用程序的默認消息處理程序（通常是應用程序的「主窗體」消息處理程序），它根據消息內容在內部處理消息。

參見：

TWinControl： http://docwiki.embarcadero.com/VCL/en/Controls.TWinControl

的TLabel： http://docwiki.embarcadero.com/VCL/en/StdCtrls.TLabel

TPanel： http://docwiki.embarcadero.com/VCL/XE/en/ExtCtrls.TPanel

Answer 3

或者您可以使用此至極適用於FreePascal的太

var 
    Form1: TForm1; 
    OldProc : Pointer; 
    counter : Integer = 0; 
implementation 

{$R *.dfm} 

function WndProc1(hw:HWND;Msg:Cardinal;wparam:WPARAM;lparam:LPARAM):LResult;stdcall; 
begin 
    if Msg = WM_SETFOCUS then 
    begin 
    Inc(counter); 
    Form1.Caption:=IntToStr(counter); 
    end; 
    Result := CallWindowProc(oldProc,hw,Msg,wparam,lparam); 
end; 

procedure TForm1.FormShow(Sender: TObject); 
var 
newproc:Pointer; 
begin 
    DWORD(OldProc) := GetWindowLong(Edit1.Handle,GWL_WNDPROC); 
    newproc := @WndProc1; 
    SetWindowLong(Edit1.Handle,GWL_WNDPROC,Integer(newproc)); 
end;