vbs如何從命令行命令獲得結果

Question

我想使用Windows腳本（.vbs）從命令行（cmd.exe）獲取簡單命令的結果。這是如何完成的？我一直無法找到一個好的/簡單的例子或解釋。您可以使用「日期」或「時間」命令來提供示例。 如：

P.S.我可以編寫打開cmd.exe的腳本代碼併發送命令。

謝謝！

Answer 1

如有疑問，請閱讀documentation。你可能想是這樣的：

Set p = CreateObject("WScript.Shell").Exec("%COMSPEC% /c date /t") 
Do While p.Status = 0 
    WScript.Sleep 100 
Loop 
WScript.Echo p.StdOut.ReadAll 

編輯：使用Exec()您通過.StdIn描述符傳輸入，而不是通過SendKeys()（這是通過輸入反正一個相當不可靠的方式）。

%COMSPEC%是與完整路徑cmd.exe和/c選項系統環境變量的命令（date /t中的例子）完成後cmd.exe出口使得。

如果該命令指出了一個退出代碼成功/失敗，您可以檢查ExitCode財產的命令結束後。

If p.Status <> 0 Then WScript.Echo p.ExitCode 

EDIT2：而不是使用atprogram交互，可以構建COMMANDLINES將無需用戶交互執行特定的任務？隨着非交互式COMMANDLINES這樣的事情可能工作：

prompt = "C:\>" 
atprogram_cmdline_1 = "atprogram.exe ..." 
atprogram_cmdline_2 = "atprogram.exe ..." 
'... 

Function ReadOutput(p) 
    text = "" 
    Do Until Right(text, Len(prompt)) = prompt 
    text = text & p.StdOut.Read(1) 
    Loop 
    ReadOutput = text 
End Function 

Set cmd = CreateObject("WScript.Shell").Exec("%COMSPEC% /k") 
ReadOutput cmd ' skip over first prompt 

cmd.StdIn.WriteLine(atprogram_cmdline_1) 
WScript.Echo ReadOutput(cmd) 
cmd.StdIn.WriteLine(atprogram_cmdline_2) 
WScript.Echo ReadOutput(cmd) 
'... 

cmd.Terminate ' exit CMD.EXE 

%COMSPEC% /k產生一個命令提示符下不運行的命令。 /k阻止它關閉。由於它不會自動關閉，因此您不能在此使用While p.Status = 0循環。如果某個命令需要一些時間才能完成，則需要WScript.Sleep秒。

通過cmd.StdIn.WriteLine可以運行在CMD實例COMMANDLINES。功能ReadOutput()讀取StdOut的輸出，直到出現下一個提示。您需要查看提示，因爲讀取操作被阻止，所以您不能簡單地說「讀取所有已打印的內容」。

完成後，您通過cmd.Terminate退出CMD.EXE。