比較SPARQL圖

Question

如何比較兩個RDF圖與SPARQL？如果我有圖表：a和：b，我想查找所有時間：a出現在：b。我可以查詢所有：a的主題，謂詞和對象，然後以編程方式構建一個模式查詢，以匹配：a中的模式：b。有沒有一種方法可以構建：SPARQL中的所有模式查詢，而不需要編程構造？

Answer 1

我建立了一個Jena Fuseki端點，其中包含兩個命名圖形http://a和http://b，我們將其稱爲A和B.A包含一個三元組，B包含兩個。 A，（看）爲一組三元的，是B的一個子集，它下面的查詢確認：

select * where { 
    graph ?g { ?s ?p ?o } 
} 

----------------------------------------------------------- 
| s   | p   | o   | g   | 
=========================================================== 
| <urn:uuid:b> | <urn:uuid:p> | <urn:uuid:b> | <http://b> | 
| <urn:uuid:a> | <urn:uuid:p> | <urn:uuid:b> | <http://b> | 
| <urn:uuid:a> | <urn:uuid:p> | <urn:uuid:b> | <http://a> | 
----------------------------------------------------------- 

現在，我們可以要求出現在一個而不是在其他三元。要問三重B中不在A，我們可以利用這個查詢：

select * where { 
    graph <http://a> { ?s ?p ?o } 
    NOT EXISTS { graph <http://b> { ?s ?p ?o } } 
} 

------------- 
| s | p | o | 
============= 
------------- 

我們也可以要求出現B中三元，而不是在答：我們希望並獲得一個三。

select * where { 
    graph <http://b> { ?s ?p ?o } 
    NOT EXISTS { graph <http://a> { ?s ?p ?o } } 
} 

---------------------------------------------- 
| s   | p   | o   | 
============================================== 
| <urn:uuid:b> | <urn:uuid:p> | <urn:uuid:b> | 
---------------------------------------------- 

一般情況下，如果X不包含三元組是不是也於Y，則X是Y的使用查詢，如上述情況，我們可以發現這樣的三元組是一個，而不是在其他的子集。

如果我們不關心特定的三元組，我們可以使用ASK查詢來檢查是否存在，而不必知道它們是什麼。例如，因爲不存在這樣的三元組，所以例如，但是，由於我們試圖詢問A 是否爲B的一個子圖，這是由它們沒有三元組表示的，所以我們需要在這裏反轉真值。所以我們使用：

ask { 
    NOT EXISTS { 
    graph <http://a> { ?s ?p ?o } 
    NOT EXISTS { graph <http://b> { ?s ?p ?o } } 
    } 
} 

yes 

同樣，如果我們問B是否是A的子圖，我們得到no：

ask { 
    NOT EXISTS { 
    graph <http://b> { ?s ?p ?o } 
    NOT EXISTS { graph <http://a> { ?s ?p ?o } } 
    } 
} 

no