返回整個陣列作爲字符串

Question

我有，如果在公式中這是一個範圍的一部分的細胞產生的「X」，即填充的數組：

Private Sub Worksheet_Change(ByVal Target As Range) 

Dim Fault(10) As Boolean 

For i = 1 To 10 

If Range("A" & i).Value = "X" Then 
    Fault(i) = True 
End If 

Next i 


MsgBox Fault 'VBA Errors Here With "Type Mismatch" 

End Sub 

我的問題是，是否有可能返回一個整個數組作爲字符串。所以在上面的例子中，如果沒有錯誤，我希望消息框返回「0000000000」。如果第7個陣列出現故障，則返回「0000001000」。

我的目的是檢查字符串總是等於「0000000000」才能繼續。但是，如果有更好的方法來檢查整個數組是否爲假，那麼這將更容易。

Answer 1

嘗試這種情況：

Sub JoinArray() 
    Dim Fault(9) As String, arrString As String 

    For i = 1 To 10 
     If Range("A" & i) = "X" Then 
      Fault(i - 1) = 1 
     Else 
      Fault(i - 1) = 0 
     End If 
    Next i 

    arrString = Join(Fault(), "") 

    If InStr(arrString, "1") Then 
     MsgBox "Fault Found" 
    Else 
     MsgBox "No faults found" 
    End If 
End Sub 

注：

1. 通常的陣列零索引，以便Fault(9)允許10個時隙例如範圍（「A1：A10」）
2. 的Join的""參數意味着有在輸出即00.11億

替代方法沒有空間，而不使用陣列

Sub FindFaults() 
    Dim rng As Range, cl As Range, faultLocations As String 

    Set rng = Range("A1:A1000") 
    faultLocations = "Faults found in the following cell(s):" & vbCrLf & vbCrLf 

    If WorksheetFunction.CountIf(rng, "X") = 0 Then 
     MsgBox "No Fault Found" 
    Else 
     For Each cl In rng 
      If cl = "X" Then 
       faultLocations = faultLocations + "Cell: " & cl.Address & vbCrLf 
      End If 
     Next cl 
    End If 

    MsgBox faultLocations 
End Sub