當超鏈接被點擊時，有沒有辦法刷新/更新形狀中的超鏈接？

Question

我在表示數據流中的進程的圖中有形狀;基於形狀和形狀名稱中的文本（例如，名爲「Control ##」的形狀，其中文本「ABC」鏈接到定義ABC過程的選項卡），形狀超鏈接到位於另一個選項卡中的過程定義。如果我將形狀中的文本更改爲「XYZ」，即是否希望超鏈接轉到「XYZ」定義，是否有自動更新該形狀中的超鏈接的方法？我嘗試過SheetFollowHyperlink事件過程，但似乎沒有發生。代碼我到目前爲止如下：

Sub AssignHyperlink() 

Dim CallerShapeName As String 
CallerShapeName = Application.Caller 

With ActiveSheet 
    Dim CallerShape As Shape 
    Set CallerShape = .Shapes(CallerShapeName) 

    Dim RowVar As Integer 

    Err.Number = 0 
    On Error Resume Next 

    If InStr(CallerShapeName, "Control") = 1 Then 

     RowVar = Application.WorksheetFunction _ 
      .Match(.Range("C2").Value & CallerShape.TextFrame2.TextRange.Text, _ 
      Sheets("Control Point Log").Range("A1:A700"), 0) 

     If (Err.Number = 1004) Then 
      MsgBox "No match found for this shape text in the Control Point Log" 
      Exit Sub 
     End If 

     On Error GoTo 0 

     .Hyperlinks.Add Anchor:=CallerShape, _ 
     Address:=ActiveWorkbook.Name & "#" & "'Control Point Log'!$C$" & RowVar 

    Else 

     RowVar = Application.WorksheetFunction _ 
      .Match(.Range("C2").Value & CallerShape.TextFrame2.TextRange.Text, _ 
      Sheets("Data Flow Glossary").Range("A1:A700"), 0) 

     If (Err.Number = 1004) Then 
      MsgBox "No match found for this shape text in the Data Flow Glossary" 
      Exit Sub 
     End If 

     On Error GoTo 0 

     .Hyperlinks.Add Anchor:=CallerShape, _ 
     Address:=ActiveWorkbook.Name & "#" & "'Data Flow Glossary'!$C$" & RowVar 

    End If 

End With 

End Sub 

Answer 1

1st。我假設你的目標是在你點擊形狀後導航到工作簿中的範圍

2nd。要導航到的範圍被命名爲範圍。

3rd。要導航的範圍等於形狀中的文本。

我的建議是使用onAction觸發形狀（assign macro時形狀的右鍵）

4RD。我們需要以下程序 - 一個適用於所有形狀。

Sub Hyperlink_Workaround() 
    On Error GoTo ErrorHandler 

    Dim curHL As String 
     curHL = ActiveSheet.Shapes(Application.Caller).TextFrame2.TextRange.Text 

    'which way do you define destination? 
    'this way you go to named range 

    Application.Goto Range(curHL), True 
    Exit Sub 
ErrorHandler: 
    MsgBox "There is no range like " & curHL 
End Sub 

5th。單擊任何形狀後，我們將在工作簿中移動到ABC或DEF範圍，然後測試，在分配上述宏的工作表上具有以下形狀。

6th。當您嘗試導航到不存在的範圍時，我爲情況添加了處理程序。