麻省理工學院計劃消息傳遞列表布爾

Question

在過去的幾天裏，我一直在關注計劃問題，包括創建一個消息傳遞過程，記錄朋友列表，然後可以操縱該列表來更改在線或離線的特定朋友的價值。如果放入的人是朋友，則返回true。如果尚未添加，則返回false。它還可以顯示在線朋友的列表，以及您擁有的另一個列表。基本上，這個想法是讓一些可以改變的Facebook追蹤器。它響應4個輸入：'添加'，切換狀態，'在線朋友和'朋友。

這是我已經成功至今獲得：

(define (sort-strings lst) 
    (sort lst string<?)) 

(define (make-facebook-list) 
(let ((T '())) 
(define (dispatch x) 
    (define (add-person name) 
(set! T (cons (cons name #f) T)) 
'done) 
    (define (online? friend) 
(eq? friend #t)) 
    (define (toggle-status! name) 
(begin ;(if() (set! T (cons (cons name #t) T))) 
    (if (member name T) 
     (set-cdr! T (cons (cons name (not (cdr name)) T)))) 
    (if (member name T) #t #f))) 
    (define (get-online-friends!) 
(sort-strings (filter online? T))) 
    (define (get-friends!) 
(sort-strings T)) 
    (cond ((eq? x 'add) add-person) 
    ((eq? x 'toggle-status) toggle-status!) 
    ((eq? x 'get-online-friends) (get-online-friends!)) 
    ((eq? x 'get-friends) (get-friends!)) 
    (else (error "Unknown Request" x)))) 
dispatch)) 

而這些是我使用的測試案例：

(define my-lst (make-facebook-list)) 
(display ((my-lst 'add) "Francis"))(newline) ; should return 'done 
(display ((my-lst 'add) "Adrian"))(newline) ; should return 'done 
(display ((my-lst 'add) "Zule"))(newline) ; should return 'done 
(display ((my-lst 'add) "Geralt"))(newline) ; should return 'done 
(display ((my-lst 'add) "Dexter"))(newline) ; should return 'done 
(display ((my-lst 'add) "Leonidas"))(newline) ; should return 'done 
(display ((my-lst 'toggle-status) "Leonidas"))(newline) ; should return #t 
(display ((my-lst 'toggle-status) "Francis"))(newline) ; should return #t 
(display ((my-lst 'toggle-status) "Zule"))(newline) ; should return #t 
(display ((my-lst 'toggle-status) "Xavier"))(newline) ; should return #f 
(display (my-lst 'get-online-friends))(newline) ; should return ("Francis" "Leonidas" "Zule") 
(display (my-lst 'get-friends)) ; should return ("Adrian" "Dexter" "Francis" "Geralt" "Leonidas" "Zule") 

我知道他們不會全部現在工作，這就是爲什麼我評論了一些程序。我試圖正確運行的那個是將狀態切換到在線或離線狀態的過程。我被引導認爲「成員」是用來檢查某個值是否是列表的一部分。我是否以這種錯誤的方式去做？

注意：排序字符串過程旨在與返回朋友列表的過程一起使用，以便按字母順序保留它們。

Answer 1

你的朋友是begin，迫使下面的表達式進行評估順序：

(define (make-facebook-list) 
    (define T '()) 
    (define (dispatch x) 
    (lambda (fl) 
     (cond ((eq? x 'add) 
      (begin 
       (set! T (append T (list fl))) 
       'done)) 
      (else 'invalid)))) 
    dispatch) 

scheme@(guile-user)> (define my-lst (make-facebook-list)) 
scheme@(guile-user)> ((my-lst 'add) "Francis") 
$1 = done 

編輯

(define (make-facebook-account) 
    (let ((*facebook-friends* '())) 
    (define (sort-alphabetically sequence) 
     (sort-list sequence string<?)) 
    (define (friend name) 
     (assoc name *facebook-friends*)) 
    (define (friends-name friend) 
     (car friend)) 
    (define (friends-status friend) 
     (cdr friend)) 
    (define (online? friend) 
     (eq? (friends-status friend) #t)) 
    (define (friend-on-facebook? name) 
     (if (member (friend name) 
        *facebook-friends*) 
      #t #f)) 
    (define (add-person! name) 
     (begin 
     (set! *facebook-friends* 
       (cons (cons name #f) 
        *facebook-friends*)) 
     'done)) 
    (define (toggle-status! name) 
     (if (friend-on-facebook? name) 
      (begin 
      (set-cdr! (friend name) 
         (if (online? (friend name)) 
          #f #t)) 
      'done) 
      (error 
      "Person no friend on facebook -- TOGGLE-STATUS!" name))) 
    (define (get-friends table) 
     (sort-alphabetically 
     (map friends-name table))) 
    (define (get-online-friends table) 
     (get-friends 
     (filter online? table))) 
    (define (dispatch m) 
     (cond ((eq? m 'add!) add-person!) 
      ((eq? m 'toggle-status!) toggle-status!) 
      ((eq? m 'get-friends) 
      (get-friends *facebook-friends*)) 
      ((eq? m 'get-online-friends) 
      (get-online-friends *facebook-friends*)) 
      ((eq? m 'friend-on-facebook?) friend-on-facebook?) 
      (else 
      (error "Unknown request -- DISPATCH" m)))) 
    dispatch))