XSLT 1.0轉換分隔字符串節點設置

Question

我有一個變量$色彩，是一個字符串

<xsl:variable name="colors" select="'red,green,blue,'" /> 

我需要一個新的變量，$ colorElements這是一個節點集

<color>red</color> 
<color>green</color> 
<color>blue</color> 

（這是對的嗎？節點集可以沒有根？）

$colorElements永遠不會直接輸出。我只需要它作爲一個列表變量。

XSLT 1.0除node-set()之外沒有擴展名。

Answer 1

用途：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
       xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"> 
    <xsl:output method="xml" indent="yes"/> 

    <xsl:variable name="colors" select="'red,green,blue,'" /> 

    <xsl:template match="/"> 

    <xsl:variable name="colorElements"> 
     <xsl:call-template name="split"> 
     <xsl:with-param name="pText" select="$colors"/> 
     </xsl:call-template> 
    </xsl:variable> 

    <xsl:for-each select="msxsl:node-set($colorElements)"> 
     <xsl:copy-of select="color"/> 
    </xsl:for-each> 

    </xsl:template> 

    <xsl:template name="split"> 
    <xsl:param name="pText"/> 

    <xsl:variable name="separator">,</xsl:variable> 

    <xsl:choose> 
     <xsl:when test="string-length($pText) = 0"/> 
     <xsl:when test="contains($pText, $separator)"> 
     <color> 
      <xsl:value-of select="substring-before($pText, $separator)"/> 
     </color> 
     <xsl:call-template name="split"> 
      <xsl:with-param name="pText" select="substring-after($pText, $separator)"/> 
     </xsl:call-template> 
     </xsl:when> 
     <xsl:otherwise> 
     <color> 
      <xsl:value-of select="$pText"/> 
     </color> 
     </xsl:otherwise> 
    </xsl:choose> 
    </xsl:template> 

</xsl:stylesheet> 

Answer 2

這個怎麼樣？：

<?xml version="1.0"?> 
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
       xmlns:xs="http://www.w3.org/2001/XMLSchema" 
       exclude-result-prefixes="xs"> 
<xsl:output method="xml" indent="yes" encoding="utf-8" /> 
<xsl:variable name="colors" select="'red,green,blue,'" /> 
<xsl:template match="/" name="main"> 
    <csv-to-xml> 
    <xsl:for-each select="tokenize($colors, ',')[position()!=last()]"> 
    <!-- The predicate is needed because of the extraneous comma 
     at the end of the red,green,blue, list. --> 
    <color><xsl:value-of select="." /></color> 
    </xsl:for-each> 
    </csv-to-xml> 
</xsl:template> 
</xsl:stylesheet>