如何從VBA函數返回結果

Question

如何從函數返回結果？

例如：

Public Function test() As Integer 
    return 1 
End Function 

這給出了一個編譯錯誤。

如何讓這個函數返回一個整數？

Answer 1

對於非對象返回類型，您必須將值分配給你的函數的名稱，如：

Public Function test() As Integer 
    test = 1 
End Function 

用法示例：

Dim i As Integer 
i = test() 

如果該函數返回一個對象類型，那麼你必須使用Set這樣的關鍵字：

Public Function testRange() As Range 
    Set testRange = Range("A1") 
End Function 

用法示例：

Dim r As Range 
Set r = testRange() 

請注意，爲函數名稱分配返回值不會終止函數的執行。如果你想退出該功能，那麼你需要明確地說Exit Function。例如：

Function test(ByVal justReturnOne As Boolean) As Integer 
    If justReturnOne Then 
     test = 1 
     Exit Function 
    End If 
    'more code... 
    test = 2 
End Function 

文檔：http://msdn.microsoft.com/en-us/library/office/gg264233%28v=office.14%29.aspx

Answer 2

VBA函數將函數名本身作爲一種變量。因此，而不是使用「return」的聲明，你只是說：

test = 1 

通知，不過，這並沒有打出來的功能。此聲明後的任何代碼也將被執行。因此，可以有許多賦值語句將不同的值賦予test，並且當到達函數結尾時的任何值都將返回值。

Answer 3

只需設置返回值函數名仍然沒有完全相同一樣的Java（或其他）return語句，因爲在Java中，return退出函數，就像這樣：

public int test(int x) { 
    if (x == 1) { 
     return 1; // exits immediately 
    } 

    // still here? return 0 as default. 
    return 0; 
} 

在VB中，如果在功能的末尾沒有設置返回值，則相當於確切需要兩行。所以，在VB確切的推論是這樣的：

Public Function test(ByVal x As Integer) As Integer 
    If x = 1 Then 
     test = 1 ' does not exit immediately. You must manually terminate... 
     Exit Function ' to exit 
    End If 

    ' Still here? return 0 as default. 
    test = 0 
    ' no need for an Exit Function because we're about to exit anyway. 
End Function 

既然是這樣的話，它也很高興知道你可以使用返回變量像法任何其他變量。就像這樣：

Public Function test(ByVal x As Integer) As Integer 

    test = x ' <-- set the return value 

    If test <> 1 Then ' Test the currently set return value 
     test = 0 ' Reset the return value to a *new* value 
    End If 

End Function 

或者極端例如如何返回變量工作（但不一定是一個很好的例子，你應該如何實際代碼）-the一個，將讓你在夜間：

Public Function test(ByVal x As Integer) As Integer 

    test = x ' <-- set the return value 

    If test > 0 Then 

     ' RECURSIVE CALL...WITH THE RETURN VALUE AS AN ARGUMENT, 
     ' AND THE RESULT RESETTING THE RETURN VALUE. 
     test = test(test - 1) 

    End If 

End Function 

Answer 4

在下面的代碼保存返回值的變量retVal然後MsgBox可用於顯示的值：

Dim retVal As Integer 
retVal = test() 
Msgbox retVal