使用Lisp將新元素推入新的空列表

Question

以下函數嘗試更新*features-list*使用元素特徵。 功能列表被定義爲全局變量。

當我運行對空*feature-list*的功能，我得到一個錯誤信息

The object is a CONDITION of type TYPE-ERROR. 
DATUM: NIL 
EXPECTED-TYPE: CONS 

然而，當我初始化*feature-list*，功能正確執行。

(defun update-feature-list (feature) 
    (let ((feature-index)) 
    (setq feature-index (position feature *features-list*)) 
    (cond ((equal feature-index nil) 
      (push feature (cdr (last *features-list*))) 
      (setq feature-index (position feature *features-list*)))))) 

Answer 1

解決方案通過this comment約書亞·泰勒提供。

您的「將某些val推入函數列表中」方法 不起作用;如果原始列表爲空，會發生什麼情況？你不能 修改汽車或cdr的空白列表;它沒有那些。 表示，如果您確實想要使用您描述的方法，那麼您可以使用(push newvalue (rest list))(rotatef (first list) (second list))更清楚一點來做 。 （這當然不是唯一的選擇， 雖然）。

Answer 2

使用標準格式。見http://www.gigamonkeys.com/book/syntax-and-semantics.html#formatting-lisp-code。

(defun update-feature-list (feature) 
    (let ((feature-index)) 
    (setq feature-index (position feature *features-list*)) 
    (cond ((equal feature-index nil) 
      ;;case 1 If feature index ==nil ;;we need to add the feature 
      (push feature (cdr (last *features-list*))) 
      (setq feature-index (position feature *features-list*)))))) 

A cond一個條款是沒有意義的。我想你的意思是when，而你 想在任何情況下更新索引，我。即條件之外。

(defun update-feature-list (feature) 
    (let ((feature-index)) 
    (setq feature-index (position feature *features-list*)) 
    (when (equal feature-index nil) 
     (push feature (cdr (last *features-list*)))) 
    (setq feature-index (position feature *features-list*)))) 

你並不需要設置一個局部變量只是回到它：

(defun update-feature-list (feature) 
    (let ((feature-index)) 
    (setq feature-index (position feature *features-list*)) 
    (when (equal feature-index nil) 
     (push feature (cdr (last *features-list*)))) 
    (position feature *features-list*))) 

您可以創建直接在let頭綁定：

(defun update-feature-list (feature) 
    (let ((feature-index (position feature *features-list*))) 
    (when (equal feature-index nil) 
     (push feature (cdr (last *features-list*)))) 
    (position feature *features-list*))) 

而不是檢查equal ... nil，使用null：

(defun update-feature-list (feature) 
    (let ((feature-index (position feature *features-list*))) 
    (when (null feature-index) 
     (push feature (cdr (last *features-list*)))) 
    (position feature *features-list*))) 

可以內聯變量：

(defun update-feature-list (feature) 
    (when (null (position feature *features-list*)) 
    (push feature (cdr (last *features-list*)))) 
    (position feature *features-list*)) 

而不是null ... position，使用not ... member：

(defun update-feature-list (feature) 
    (when (not (member feature *features-list*)) 
    (push feature (cdr (last *features-list*)))) 
    (position feature *features-list*)) 

在列表的最後一個利弊的cdr是不是一個地方，你會想推 東西。我想你想append，但在大多數情況下，你應該 而不是推到列表的前端，這是更有效的。 對此也有pushnew。回到新的位置不 多大意義了，但是：

(defun update-feature-list (feature) 
    (pushnew feature *features-list*) 
    (position feature *features-list*)) 

如果你真的需要這種順序和位置，可以使用可調節的載體來代替：

(defvar *features-list* (make-array 10 
            :adjustable t 
            :fill-pointer 0)) 

(defun add-feature (feature) 
    (or (position feature *features-list*) 
     (vector-push-extend feature *features-list*))) ; v-p-e returns the index