將基本ActionScript 2轉換爲ActionScript 3用於翻轉動畫

Question

所以，我想要做的事情應該很簡單。這只是一個翻轉動畫，當用戶將鼠標關閉時會反轉。事情是，它在AS2中，但我認爲要完成該項目，我將在AS3中使用它。任何人都可以提供一些意見上的轉換這...

stop(); 

this.onEnterFrame = function(){ 
if(rewind == true){ 
prevFrame(); 
} 
} 

this.onRollOver = function(){ 
rewind = false; 
play(); 
} 

this.onRollOut = function(){ 
rewind = true; 
} 

this.onRelease = function(){ 
getURL("http://www.google.com","_blank"); 
} 

...到AS3？我會非常感激。

Answer 1

如果你的代碼需要限制這些，你應該學會如何在AS3中完成它。

在這裏，在AS3完全一樣的事情

import flash.events.Event; 
import flash.events.MouseEvent; 
import flash.net.navigateToURL; 
import flash.net.URLRequest; 

stop(); 
addEventListener(Event.ENTER_FRAME, onEnterFrame); 
addEventListener(MouseEvent.MOUSE_OVER, onMouseOver); 
addEventListener(MouseEvent.MOUSE_OUT, onMouseOut); 
addEventListener(MouseEvent.CLICK, onClick); 

var rewind:Boolean = false; 

function onEnterFrame(event:Event):void 
{ 
    if (rewind == true) { 
     prevFrame(); 
    } 
} 

function onMouseOver(event:MouseEvent):void 
{ 
    rewind = false; 
    play(); 
} 

function onMouseOut(event:MouseEvent):void 
{ 
    rewind = true; 
} 

function onClick(event:MouseEvent):void 
{ 
    navigateToURL(new URLRequest("http://www.google.com"),"_blank"); 
} 

請注意，而不是創建一個監聽到的事件（翻滾例如）通過寫this.onRollOver = function()，你確實有調用addEventListener（這是非常合乎邏輯），指定要偵聽的事件並創建一個在捕獲此事件時調用的函數。

也有在getURL另一個區別 - >navigateToURL，但我認爲它:)

作爲感謝你不需要任何進一步的解釋，我真的很感謝你閱讀這段代碼，並嘗試從中學習，而不是大致複製/粘貼。但是，嘿，你是免費的！