批量條件FOR循環嵌套IF

Question

我正試圖編寫一個腳本來解析一個文本文件，以標識可移動驅動器。目標是根據找到的驅動器創建一個副本腳本。

我能夠解析文件，但我似乎無法得到第二對IF條件爲真。

我可能會誤解在FOR的每個循環中如何評估變量。

想法感激。

編輯：爲了清晰起見擴展原始請求（我問的時候已經很晚了）擴展目標是確定一個或多個目標驅動器從SD卡複製數據。由於驅動器字母分配從PC改變PC和依賴於它在第一插入我的想法是使用標籤作爲有些身份價值，同時

XCOPY SourceDrive\*.jpg DestinationDrive1\<GetDate>\ 
XCOPY SourceDrive\*.jpg DestinationDrive2\<GetDate>\ 

結束的行創建一個簡單的複製串編輯

@echo off 
cls 
title "Detecting device drive letters..." 
setlocal enabledelayedexpansion 
set DestinationDrive1Found= 
set DestinationDrive2Found= 
set SourceDriveFound= 
set SourceDrive= 
set DestinationDrive1= 
set DestinationDrive2= 

echo Detecting device drive letters... 

echo list volume > %systemdrive%\ListDrives.tmp 
diskpart /s %systemdrive%\ListDrives.tmp > %systemdrive%\CurrentDrives.tmp 

echo Checking drive IDs 
FOR /F "skip=7 tokens=2-4" %%a IN (%systemdrive%\CurrentDrives.tmp) DO ( 
set "matchvar=%%c" 
set "comparevar=!matchvar:DRIVE=!" 
IF /I NOT "!comparevar!" == "%%c" IF "!DestinationDrive1Found!" NEQ 1 (
echo Drive %%b was found to be %%c and will be DESTINATION1 
set DestinationDrive1Found=1 
set DestinationDrive1=%%b) 
IF /I NOT "!comparevar!" == "%%c" IF "!DestinationDrive1Found!" EQU 1 (echo Drive %%b was found to be %%c and will be DESTINATION2 
set DestinationDrive2Found=1 
set DestinationDrive2=%%b) 
)  

文件我解析

Microsoft DiskPart version 10.0.10586 

Copyright (C) 1999-2013 Microsoft Corporation. 
On computer: NEWGLOOMWIN10 

    Volume ### Ltr Label  Fs  Type  Size  Status  Info 
    ---------- --- ----------- ----- ---------- ------- --------- -------- 
    Volume 0  D      DVD-ROM   0 B No Media   
    Volume 1  E Macintosh H HFS Partition 231 GB Healthy    
    Volume 2  C BOOTCAMP  NTFS Partition 721 GB Healthy System 
    Volume 3  F TEAMXCAMRAX FAT Removable 1937 MB Healthy    
    Volume 4  G TEAMXDRIVEX NTFS Partition 465 GB Healthy    
    Volume 5  H TEAMYDRIVEY NTFS Partition 931 GB Healthy 

Answer 1

感謝所有回答。如果@Mofi提供了答案，我會將該答覆標記爲答案。最後，刪除了四個引號，並添加了一個ELSE，讓我得到了我正在尋找的答案。

下面的腳本給了我完全一樣的東西。

@echo off 
cls 
title "Detecting device drive letters..." 
setlocal enabledelayedexpansion 
set DestinationDrive1Found= 
set DestinationDrive2Found= 
set SourceDriveFound= 
set SourceDrive= 
set DestinationDrive1= 
set DestinationDrive2= 

echo Detecting device drive letters... 

echo list volume > %systemdrive%\ListDrives.tmp 
diskpart /s %systemdrive%\ListDrives.tmp > %systemdrive%\CurrentDrives.tmp 


echo Checking drive IDs 
FOR /F "skip=7 tokens=2-4" %%a IN (%systemdrive%\CurrentDrives.tmp) DO ( 
set "matchvar=%%c" 
set "comparevar=!matchvar:CAMRA=!" 
IF /I NOT "!comparevar!" == "%%c" (@echo Drive %%b was found to be %%c and will be SOURCE 
set SourceDriveFound=1 
set SourceDrive=%%b) 
) 

echo Checking drive IDs 
FOR /F "skip=7 tokens=2-4" %%a IN (%systemdrive%\CurrentDrives.tmp) DO ( 
set "matchvar=%%c" 
set "comparevar=!matchvar:DRIVE=!" 
IF /I NOT "!comparevar!" == "%%c" IF !DestinationDrive1Found! NEQ 1 (
echo Drive %%b was found to be %%c and will be DESTINATION1 
set DestinationDrive1Found=1 
set DestinationDrive1=%%b 
) ELSE ( 
IF /I NOT "!comparevar!" == "%%c" IF !DestinationDrive1Found! EQU 1 (echo Drive %%b was found to be %%c and will be DESTINATION2 
set DestinationDrive2Found=1 
set DestinationDrive2=%%b)) 
) 

Answer 2

如果你只是想將一些變量分配給驅動器任何可拆卸驅動器的字符串DRIVE在它的'標籤'中，那麼以下內容可能會爲您提供一個不需要提升的替代方案。

@Echo Off 
For /F "UseBackQ Skip=1 Delims=" %%A In (`WMIC LogicalDisk Where^ 
"DriveType='2' And VolumeName Like '%%DRIVE%%'" Get Name` 
) Do For /F %%B In ("%%A") Do Set/A "i+=1"&Call Set "_drv%%i%%=%%B" 
Set _drv 
Timeout -1 

[編輯] - 一個例子正確規定固定的驅動

@Echo Off 
For /F "UseBackQ Skip=1 Delims=" %%A In (`WMIC LogicalDisk Where^ 
"DriveType='3' And VolumeName Like '%%DRIVE%%'" Get Name` 
) Do For /F %%B In ("%%A") Do Set/A "i+=1"&Call Set "_drv%%i%%=%%B" 
Set _drv 
Timeout -1 

一個例子而未規定驅動，的類型（基於評論推薦）。

@Echo Off 
For /F "UseBackQ Skip=1 Delims=" %%A In (
    `WMIC LogicalDisk Where "VolumeName Like '%%DRIVE%%'" Get Name` 
) Do For /F %%B In ("%%A") Do Set/A "i+=1"&Call Set "_drv%%i%%=%%B" 
Set _drv 
Timeout -1