執行和等待有時不工作

Question

我正在使用此代碼，我在互聯網上找到它，並在某些設備上等待，但在其他設備上沒有。有人可以解釋我哪裏出錯了。我的應用程序在Truecrypt中加載，然後等待用戶輸入密碼。退出Truecrypt後，它會啓動我的菜單程序。我的聯想Miix 2 8「平板電腦，win8.1（所有最新）將等待，我爸爸的win8.0（全部最新）將等待，但我朋友的華碩M80TA 8」win8.1平板電腦（所有最新）將等待，我的朋友的華碩M80TA 8「win8.1平板電腦（所有最新）不會。另一位朋友的win7筆記本電腦（全部是最新的）不會等待以太網。

var 
    aTSI : TStartupInfo; 
    aTPI : TProcessInformation; 
    iRet : Integer; 
    ExitCode: Cardinal; 
begin 
    FillChar(aTSI, SizeOf(aTSI), #0); 
    FillChar(aTPI, SizeOf(aTPI), #0); 
    aTSI.CB:=SizeOf(aTSI); 
    if not CreateProcess(nil, PChar(sEXE), nil, nil, False, 
         NORMAL_PRIORITY_CLASS, 
         nil, nil, aTSI, aTPI) then 
    RaiseLastWin32Error; 
    repeat 
    iRet:=MsgWaitForMultipleObjects(1, aTPI.hProcess, 
    False, INFINITE, (QS_ALLINPUT)); 
    if iRet <> (WAIT_OBJECT_0) then 
     Application.ProcessMessages; 
    until iRet = (WAIT_OBJECT_0); // use this for normal programs 
    ExitCode:= 0; 
    if not GetExitCodeProcess(aTPI.hProcess, ExitCode) then 
    RaiseLastWin32Error; 
    Result:= ExitCode; 
    CloseHandle(aTPI.hProcess); 
end; 

Answer 1

可能的解釋如下：

1. 你打電話的CreateProcess這將創建一個新的進程，並返回一個句柄這一進程。
2. 第一個新過程反過來開始一個不同的過程，並立即返回。第二個過程就是您所看到的過程，並且相信這是您創建的過程。
3. 您等待第一個進程句柄返回。

爲了解如何處理這個問題，您需要提供一些關於您嘗試啓動的過程的詳細信息。至於爲什麼代碼可以在某些機器上運行，而不是其他機器上運行的代碼，那很可能是目標應用程序的實現細節，即您所啓動的外部應用程序。據推測，它不同於機器。

看着代碼，它總是泄漏aTPI.hThread中返回的線程句柄。如果GetExitCodeProcess失敗，它會泄漏aTPI.hProcess。

您還需要確保傳遞給命令行參數CreateProcess的字符串是可編輯的字符串，而不是存儲在只讀存儲器中的文字。

初始化ExitCode然後立即覆蓋它也是毫無意義的。更重要的是，您可以刪除ExitCode變量並將Result直接傳遞給GetExitCodeProcess。

您的代碼也無法確認等待函數返回的錯誤。

我可能會寫這樣的：

function ExecAndWait(CommandLine: string): DWORD; 
var 
    si: TStartupInfo; 
    pi: TProcessInformation; 
    iRet: Integer; 
begin 
    UniqueString(CommandLine); 
    si := Default(TStartupInfo); 
    si.cb := SizeOf(si); 
    Win32Check(CreateProcess(nil, PChar(CommandLine), nil, nil, False, 
    NORMAL_PRIORITY_CLASS, nil, nil, si, pi)); 
    CloseHandle(pi.hThread); 
    try 
    while True do 
    begin 
     iRet := MsgWaitForMultipleObjects(1, pi.hProcess, False, INFINITE, QS_ALLINPUT); 
     Win32Check(iRet <> WAIT_FAILED); 
     case iRet of 
     WAIT_OBJECT_0: 
     break; 
     WAIT_OBJECT_0+1: 
     Application.ProcessMessages; 
     end; 
    end; 
    Win32Check(GetExitCodeProcess(pi.hProcess, Result)); 
    finally 
    CloseHandle(pi.hProcess); 
    end; 
end; 

在我的機器，當我通過'notepad.exe'這個函數，該函數不返回，直到記事本進程被關閉。

另一方面，如果我將'explorer.exe'傳遞給進程，則該函數立即返回。這裏發生的是一個新的瀏覽器進程啓動，但它檢測到一個已經運行，並要求該進程打開一個新窗口。新啓動的瀏覽器進程立即終止。