匹配一個正則表達式在TCL PERL

Question

我有follwing模式

Pattern[1]: 
    Key : "key1" 
    Value : 100 
    Pattern[2]: 
    Key : "key2" 
    Value : 20 
    Pattern[3]: 
    Key : "key3" 
    Value : 30 
    Pattern[4]: 
    Key : "key4" 
    Value : 220 

我想每個隔離塊Pattern。我正在使用TCL。正則表達式，我使用是不解析目的

set updateList [regexp -all -inline {Pattern\[\d+\].*?Value.*?\n} $list] 

這正則表達式用來分隔每個模式

我需要爲

Pattern[1]: 
    Key : "key1" 
    Value : 100 


    Pattern[2]: 
    Key : "key2" 
    Value : 20 


    Pattern[3]: 
    Key : "key3" 
    Value : 30 


    Pattern[4]: 
    Key : "key4" 
    Value : 220 

Answer 1

你的模式Pattern\[\d+\].*?Value.*?\n包含混合量詞：既貪婪又懶惰。 Tcl並不像您期望的那樣處理混合量詞類型，例如PCRE（PHP，Perl），.NET等，它默認爲第一個找到的類型，因爲隨後的量詞繼承了前面的量詞類型。所以，\d之後的+是貪婪的，因此，所有其他人（在.*?中）也是貪婪的 - 即使你宣稱它們是懶惰的。此外，.也與Tcl正則表達式中的換行符匹配，因此，您的模式的工作方式與this類似。

所以，根據你的正則表達式，你可以使\d+慵懶\d+?，並在與(?:\n|$)末取代\n同時匹配換行和字符串的結尾：

set RE {Pattern\[\d+?\].*?Value.*?(?:\n|$)} 
set updateList [regexp -all -inline $RE $str] 

見IDEONE demo

替代1

此外，您還可以使用更詳細的正則表達式，如果你輸入的字符串始終具有相同的結構與所有元素 - Pattern，Key，Value - 至今：

set updateList [regexp -all -inline {Pattern\[\d+\]:\s*Key[^\n]*\s*Value[^\n]*} $str] 

見IDEONE demo，這裏是regex demo。

由於.可以匹配一個換行符，因此我們需要使用一個[^\n]否定字符類來匹配除換行符之外的任何字符。

替代2

您可以使用展開懶子模式匹配Pattern[n]:，然後任何字符，這並不是一個Pattern[n]:序列的起點：

set RE {Pattern\[\d+\]:[^P]*(?:P(?!attern\[\d+\]).)*} 
set updateList [regexp -all -inline $RE $str] 

見another IDEONE demo和regex101 demo

Answer 2

輸出試試這個

Pattern\[\d+\](.|\n)*?Value.*?\n 

的點。字符匹配任何字符，但斷行，所以你需要將其添加到。要知道，你的行可能以回車字符結束，所以你可能需要在加\ r。

Answer 3

你想要捕捉線條塊，並輸出它們之間的空行。您的示例數據顯示不同級別的模式，可用於識別哪些線路屬於哪個模塊。

最簡單的模式是：輸入中的每三行組成一個塊。此模式建議如下處理：

set lines [split [string trim $list \n] \n] 
foreach {a b c} $lines {puts $a\n$b\n$c\n\n} 

示例數據中沒有任何內容表明這不起作用。不過，您的示例數據中可能會有一些併發症未反映出來。

如果有輸入流浪空行，你可能需要得到第一個擺脫他們：

set lines [lmap line $lines {if {[string is space $line]} continue else {set line}}] 

如果某些塊包含更少或更多的線比你的榜樣，另一個簡單的模式是，每塊以具有可選（？）空格和單詞Pattern的行開始。這些線路（除第一）應當由輸出塊分隔符前面：

set lines [split [string trim $list \n] \n] 
puts [lindex $lines 0] 
foreach line [lrange $lines 1 end] { 
    if {[regexp {\s*Pattern} $line]} { 
     puts \n$line 
    } else { 
     puts $line 
    } 
} 
puts \n 

如果線實際上並不空白開始，你可以使用string match Pattern* $line而不是正則表達式。

文檔：continue，foreach，if，lindex，lmap，lmap更換，lrange，puts，regexp，set，split，string

Answer 4

% set list { Pattern[1]: 
    Key : "key1" 
    Value : 100 
    Pattern[2]: 
    Key : "key2" 
    Value : 20 
    Pattern[3]: 
    Key : "key3" 
    Value : 30 
    Pattern[4]: 
    Key : "key4" 
    Value : 220 
} 
% regexp -all -inline {Pattern\[\d+\].*?Value.*?\n} $list 
{Pattern[1]: 
    Key : "key1" 
    Value : 100 
    Pattern[2]: 
    Key : "key2" 
    Value : 20 
    Pattern[3]: 
    Key : "key3" 
    Value : 30 
    Pattern[4]: 
    Key : "key4" 
    Value : 220 
} 
% regexp -all -inline {Pattern\[\d+?\].*?Value.*?\n} $list ;# only changing `\d+` to `\d+?` 
{Pattern[1]: 
    Key : "key1" 
    Value : 100 
} {Pattern[2]: 
    Key : "key2" 
    Value : 20 
} {Pattern[3]: 
    Key : "key3" 
    Value : 30 
} {Pattern[4]: 
    Key : "key4" 
    Value : 220 
} 

如果$列表確實不末以新行，你將不會得到返回的「pattern [4]」元素。在這種情況下，改變

% regexp -all -inline {Pattern\[\d+?\].*?Value.*?\n} $list 

到

% regexp -all -inline {Pattern\[\d+?\].*?Value.*?(?:\n|$)} $list