perl讀取文件並抓取特定行

Question

我有一個文本文件，我想抓住特定的行，以模式開始並以特定模式結束。 示例：

Text 
Text 
Startpattern 
print this line 
Print this line 
print this line 
Endpattern 
Text 
Text 
Text 

此外，還應打印起始圖案和結束圖案。我的第一次嘗試不是很成功：

my $LOGFILE = "/var/log/logfile"; 
my @array; 
# open the file (or die trying) 

open(LOGFILE) or die("Could not open log file."); 
foreach $line() { 
    if($line =~ m/Sstartpattern/i){ 
    print $line; 
    foreach $line2() { 
     if(!$line =~ m/Endpattern/i){ 
     print $line2; 
     } 
    } 
    } 
} 
close(LOGFILE); 

在此先感謝您的幫助。

Answer 1

如何：

#!perl -w 
use strict; 

my $spool = 0; 
my @matchingLines; 

while (<DATA>) { 
    if (/StartPattern/i) { 
     $spool = 1; 
     next; 
    } 
    elsif (/Endpattern/i) { 
     $spool = 0; 
     print map { "$_ \n" } @matchingLines; 
     @matchingLines =(); 
    } 
    if ($spool) { 
     push (@matchingLines, $_); 
    } 
} 

__DATA__ 

Text 
Text 
Startpattern 
print this line 
Print this line 
print this line 
Endpattern 
Text 
Text 
Text 
Startpattern 
print this other line 
Endpattern 

如果你也想打印的開始和結束模式，加推聲明中，如果塊爲好。

Answer 2

您可以使用標range operator：

open my $fh, "<", $file or die $!; 

while (<$fh>) { 
    print if /Startpattern/ .. /Endpattern/; 
} 

Answer 3

像這樣的事情？

my $LOGFILE = "/var/log/logfile"; 
open my $fh, "<$LOGFILE" or die("could not open log file: $!"); 
my $in = 0; 

while(<$fh>) 
{ 
    $in = 1 if /Startpattern/i; 
    print if($in); 
    $in = 0 if /Endpattern/i; 
}