減去值

Question

我輸入文件如下

100A 2000 
100B 150 
100C 800 
100A 1000 
100B 100 
100C 300 

我想減去第2列值在列中的每個uniq的值1 所以出來放應該像

100A 1000 
100B 50 
100C 500 

我已經試過

awk '{if(!a[$1])a[$1]=$2; else a[$1]=$2-a[$1]}END{ for(i in a)print i" " a[i]}' file 

但放出來是：

100A 0 
100B 0 
100C 0 

請指教

Answer 1

這麼多的（輕微）的變化同一主題。

awk ' 
    !($1 in a) {a[$1]=$2; next} 
    {a[$1]-=$2} 
    END {for (i in a) printf "%s %d\n",i,a[i]} 
' input.txt 

如果您願意，可將其疊加爲一行。

請記住，awk結構由多個condition { statement }對組成，因此您可以比使用if..else更優雅地表達您的需求。 （並不是說這裏就是這種情況 - 這是一個足夠簡單的awk腳本，它可能並不重要，除非你是一個純粹主義者。]）

另外，要小心測試值的方式，已經在你的if的條件下完成了這個問題。請注意，a[$1]都測試該數組索引處的值是否爲非零值和如果先前不存在，則會使索引存在空值。如果您想檢查索引是否存在，請使用$1 in a。

---

更新基於對您的問題評論...

如果你想減去從第一項最後，忽略之間的，那麼你需要保持記錄你的第一個和你的最後一個。像這樣的東西可能就足夠了。

awk ' 
    !($1 in a){a[$1]=$2;next} 
    {b[$1]=$2} 
    END {for(i in b)if(i in a)print i,a[i]-b[i]} 
' input.txt 

請注意，正如埃德提到的，這會產生隨機順序的輸出。如果你想要輸出的順序，你需要一個額外的數組來跟蹤訂單。例如，這將使用順序的項目，首先看出：

awk ' 
    !($1 in a) { 
    a[$1]=$2; 
    o[++n]=$1; 
    next 
    } 
    { 
    b[$1]=$2 
    } 
    END { 
    for (n=1;n<=length(o);n++) 
     print o[n],a[o[n]]-b[o[n]] 
    } 
' i 

注意，所使用的length()函數來確定數組中元素的數目是不普遍之中AWK的方言，但它確實在兩個工作gawk和one-true-awk（用於FreeBSD等）。

Answer 2

這AWK的一行這項工作：

awk '{if($1 in a)a[$1]=a[$1]-$2;else a[$1]=$2} 
     END{for(x in a) print x, a[x]}' file 

Answer 3

您可以使用此awk：

awk 'a[$1]{a[$1]=a[$1]-$2; next} {a[$1]=$2} END{for(v in a){print v, a[v]}}' file 

Answer 4

在awk中。使用條件運算符值配售/減法，以保持緊：

$ awk '{ a[$1]+=($1 in a?-$2:$2) } END{ for(i in a)print i, a[i] }' file 
100A 1000 
100B 50 
100C 500 

解釋：

{ 
    a[$1]+=($1 in a?-$2:$2) # if $1 in a already, subtract from it 
           # otherwise add value to it 
} 
END { 
    for(i in a)    # go thru all a 
     print i, a[i]   # and print keys and values 
} 

Answer 5

給你提供的樣品輸入，所有你需要的是：

$ awk '$1 in a{print $1, a[$1]-$2} {a[$1]=$2}' file 
100A 1000 
100B 50 
100C 500 

如果是這樣的不是所有你需要的，然後提供更真實的代表性樣本輸入/輸出，包括那些不夠好的情況。