XSLT刪除標籤的子元素，但保留內容

Question

我有以下結構的XML：

<tuple> 
    <something>One</something> 
    <somethingelse>Two</somethingelse> 
    <somethingextra> 
     <tuple> 
      <somethingextra2>Three</somethingextra2> 
     </tuple> 
    </somethingextra> 
</tuple> 

我試圖找出如何刪除子<tuple>元素，同時保持內容。

<tuple> 
    <something>One</something> 
    <somethingelse>Two</somethingelse> 
    <somethingextra> 
     <somethingextra2>Three</somethingextra2> 
    </somethingextra> 
</tuple> 

任何幫助或建議將非常受歡迎。

Answer 1

michael.hor257k出色地回答了這個問題。 這是我的變化，也處理了我有一些其他變化。

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" version="1.0" encoding="UTF-8" 
    indent="yes" /> 
    <xsl:template match="@* | node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@* | node()" /> 
     </xsl:copy> 
    </xsl:template> 
    <!-- Convert any atom, table or tuple element to a new element with the name attribute as the element name --> 
    <xsl:template match="atom[@name] | table[@name] | tuple[@name]"> 
     <xsl:element name="{@name}"> 
      <xsl:apply-templates /> 
     </xsl:element> 
    </xsl:template> 
</xsl:stylesheet> 

Answer 2

您需要一種方法來區分要刪除的根元素tuple元素和tuple元素。

例如，這將刪除具有父元素任何tuple元素：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<!-- identity transform --> 
<xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="*/tuple"> 
    <xsl:apply-templates/> 
</xsl:template> 

</xsl:stylesheet> 

Answer 3

你也可以切換到一個額外的模式，同時遍歷你的XML樹。在標準模式下複製所有元素，但在模式'noTuple'中，您跳過節點複製並返回到正常模式。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:template match="somethingextra"> 
    <xsl:copy> 
     <!-- here you switch the mode --> 
     <xsl:apply-templates select="*" mode="noTuple"/> 
    </xsl:copy> 
    </xsl:template> 

    <!-- in standard mode - copy the node an go on in standard mode --> 
    <xsl:template match="*"> 
     <xsl:copy> 
      <xsl:apply-templates select="*|text()"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="text()"> 
    <xsl:value-of select="."/> 
    </xsl:template> 

    <!-- matches only for tuple nodes in extra mode --> 
    <xsl:template match="tuple" mode="noTuple"> 
     <!-- back to normal mode --> 
     <xsl:apply-templates select="*|text()"/> 
    </xsl:template> 

    <!-- in extra mode - copy the node an go on in extra mode --> 
    <xsl:template match="*" mode="noTuple"> 
     <xsl:copy> 
      <xsl:apply-templates select="*|text()" mode="noTuple"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="text()" mode="noTuple"> 
    <xsl:value-of select="."/> 
    </xsl:template> 

</xsl:stylesheet>