如何從分隔的文本

Question

得到一個特定的領域我有分隔文本即一個字符串： 值1：值2：值3：值4：值5：Value6

我將如何提取，例如，一個特定的值，即： Label.caption := GetValuefromDelimitedText(2);獲得值2

在此先感謝

保羅

Answer 1

這應做到：

function GetValueFromDelimitedText(
    const s: string; 
    const Separator: char; 
    const Index: Integer 
): string; 
var 
    i, ItemIndex, Start: Integer; 
begin 
    ItemIndex := 1; 
    Start := 1; 
    for i := 1 to Length(s) do begin 
    if s[i]=Separator then begin 
     if ItemIndex=Index then begin 
     Result := Copy(s, Start, i-Start); 
     exit; 
     end; 
     inc(ItemIndex); 
     Start := i+1; 
    end; 
    end; 
    if ItemIndex=Index then begin 
    Result := Copy(s, Start, Length(s)-Start+1); 
    end else begin 
    Result := ''; 
    end; 
end; 

這個版本允許你指定分隔符，你顯然會通過':'。如果你要求一個超出結尾的項目，那麼函數將返回空字符串。如果您願意，可以將其更改爲例外。最後，我已經安排，這使用基於1的索引按照您的示例，但我個人會選擇基於0的索引。

Answer 2

類似的東西 - 如果你喜歡緊湊的代碼（但不作爲高性能的戴維斯）：

function GetValueFromDelimitedText(const s: string; Separator: char; Index: Integer): string; 
var sl : TStringList; 
begin 
    Result := ''; 
    sl := TStringList.Create; 
    try 
     sl.Delimiter := Separator; 
     sl.DelimitedText := s; 
     if sl.Count > index then 
      Result := sl[index]; 
    finally 
      sl.Free; 
    end; 
end; 

希望幫助

Answer 3

如果採用Delphi XE或更高版本，你也可以使用StrUtils.SplitString這樣的：

function GetValueFromDelimitedText (const Str: string; Separator: Char; Index: Integer) : string; 

begin 
Result := SplitString (Str, Separator) [Index]; 
end; 

在生產代碼中，您應該檢查Index確實是一個有效的索引。

此方法返回TStringDynArray（字符串動態數組），所以也可以使用它像這樣（使用枚舉）：

for Str in SplitString (Str, Separator) do 
    Writeln (Str); 

其可以是非常有用的IMHO。