批量歸檔文件

我正在製作一個腳本，可以讓我歸檔給定目錄中最後修改日期優於30天的所有文件。這些文件應該被移動到一個新的文件夾，然後這個文件夾必須被壓縮。批量歸檔文件

Aditionaly - 這有點殘酷 - 在歸檔過程中，文件應按月分組。壓縮文件夾的名稱應指示包含文件的月份和年份。

實施例： 2012_12.zip（包含來自2012年12月的所有文件）; 2013_01.zip（包含所有文件從2013年1月）

這是我到目前爲止有：

ECHO OFF 

ECHO. 
SET /p folder=Which folder you want to archive? 
ECHO. 
ECHO %folder% 

CHDIR %folder% 
MKDIR Archive 

ROBOCOPY "%folder%" "%folder%\Arquivo" /E /V /ETA /MOVE /XD "%folder%\Archive" 
:: Exclude files newer than 30 days 

FORFILES /P "%folder%\Archive" /D -31/12/2012 /D +1/12/2012 /C GOTO :ZIP 




CALL:ZIP 
SET filetozip="%folder%\Archive" 
set tempdir=C:\Users\tiago.campos\Documents\OMS\FilesArchiver\tempdir 
mkdir %tempdir% 
copy %filetozip% %tempdir% 
mkdir "%filetozip%\Archive" 
rmdir %tempdir% 
realdate 

echo Set objArgs = WScript.Arguments > _zipIt.vbs 
echo InputFolder = objArgs(0) >> _zipIt.vbs 
echo ZipFile = objArgs(1) >> _zipIt.vbs 
echo CreateObject("Scripting.FileSystemObject").CreateTextFile(ZipFile, True).Write "PK" ^& Chr(5) ^& Chr(6) ^& String(18, vbNullChar) >> _zipIt.vbs 
echo Set objShell = CreateObject("Shell.Application") >> _zipIt.vbs 
echo Set source = objShell.NameSpace(InputFolder).Items >> _zipIt.vbs 
echo objShell.NameSpace(ZipFile).CopyHere(source) >> _zipIt.vbs 
echo wScript.Sleep 2000 >> _zipIt.vbs 


CScript _zipIt.vbs %tempdir% "%filetozip%\Archive\2013.01.zip" 

del "_zipIt.vbs" 

pause

作爲獎勵的功能，這將是非常有用的，如果不是施捨的目錄一個輸入，腳本會從一個csv文件中讀取多個目錄。

我有點迷失在這個momement。我預先感謝每一個回覆！

來源

2013-02-21 user2096251

由於你已經在使用vbscript進行壓縮，並且vbscript對於用日期執行算術也更好，所以不妨在vbscript中做整個事情。

我沒有做csv的事情，但也許你可以調用腳本批量for %%I in (csvfile) do cscript /nologo archive.vbs %%I或類似的。如果沒有參數傳遞，它將歸檔當前的工作目錄。

' archive.vbs 
' usage: cscript archive.vbs (directory, optional) 

if not wscript.arguments.count then 
    dir = left(WScript.ScriptFullName,(Len(WScript.ScriptFullName))-(len(WScript.ScriptName))) 
else 
    dir = wscript.arguments(0) 
    if not Right(dir, 1) = "\" then 
     dir = dir & "\" 
    end if 
end if 

set fso = createobject("scripting.filesystemobject") 
set shl = createobject("shell.application") 
set osh = createobject("wscript.shell") 
set files = fso.getFolder(dir).files 
dim zips 
dim folders 
redim zips(-1) 
redim folders(-1) 

for each file in files 
    if DateDiff("d", file.datelastmodified, Date()) > 30 then 
     yyyymm = DatePart("yyyy", file.datelastmodified) & "_" & Right("0" & DatePart("m", file.datelastmodified), 2) 
     dest = dir & yyyymm & "\" 
     if not fso.folderexists(dest) then 
      fso.createFolder dest 
      zip = dir & yyyymm & ".zip" 
      redim preserve zips(ubound(zips) + 1) 
      redim preserve folders(ubound(folders) + 1) 
      zips(ubound(zips)) = zip 
      folders(ubound(folders)) = dest 
     end if 
     Wscript.echo "Moving " & file & " to " & dest 
     fso.moveFile file, dest 
    end if 
next 

set files = nothing 

Wscript.echo "Copying finished." 

on error resume next 
for i = lbound(zips) to ubound(zips) 
    Wscript.echo i & ": Zipping " & folders(i) & " to " & zips(i) 
    set zip = fso.createtextfile(zips(i)) 
    zip.write "PK" & chr(5) & chr(6) & string(18, chr(0)) 
    zip.close 
    set zip = Nothing 
    shl.namespace(zips(i)).copyhere shl.namespace(folders(i)).items 
    do until shl.namespace(zips(i)).items.count = shl.namespace(folders(i)).items.count 
     wscript.sleep 100 
    loop 

    ' This method of deleting folders is more reliable than fso.deletefolder 
    ' for paths with long filenames. 
    osh.run "cmd /c rmdir /q /s """ & folders(i) & """", 1, true 
next 

Wscript.Echo "Done."

來源

2013-02-22 16:34:47 rojo

批量歸檔文件

回答

相關問題