Adob​​e Air如何檢查URL是否在線\給出任何響應存在？

Question

我有網址我想檢查它是否存在。我想獲得bool價值。如何做這樣的事情？

Answer 1

您可以使用URLLoader並偵聽事件以檢查它是否加載，如果不是，可能是什麼問題。如果首先使用AIRMonitor來確保客戶端計算機處於聯機狀態，將會非常方便。

這是一類我開始寫來說明這個想法：

package 
{ 
    import flash.events.Event; 
    import flash.events.EventDispatcher; 
    import flash.events.HTTPStatusEvent; 
    import flash.events.IEventDispatcher; 
    import flash.events.IOErrorEvent; 
    import flash.events.SecurityErrorEvent; 
    import flash.net.URLLoader; 
    import flash.net.URLRequest; 

    /** 
    * ... 
    * @author George Profenza 
    */ 
    public class URLChecker extends EventDispatcher 
    { 
     private var _url:String; 
     private var _request:URLRequest; 
     private var _loader:URLLoader; 
     private var _isLive:Boolean; 
     private var _liveStatuses:Array; 
     private var _completeEvent:Event; 
     private var _dispatched:Boolean; 
     private var _log:String = ''; 

     public function URLChecker(target:IEventDispatcher = null) 
     { 
      super(target); 
      init(); 
     } 

     private function init():void 
     { 
      _loader = new URLLoader(); 
      _loader.addEventListener(Event.COMPLETE, _completeHandler); 
      _loader.addEventListener(HTTPStatusEvent.HTTP_STATUS, _httpStatusHandler); 
      _loader.addEventListener(IOErrorEvent.IO_ERROR, _ioErrorEventHandler); 
      _loader.addEventListener(SecurityErrorEvent.SECURITY_ERROR, _securityErrorHandler); 

      _completeEvent = new Event(Event.COMPLETE, false, true); 

      _liveStatuses = [];//add other acceptable http statuses here 
     } 

     public function check(url:String = 'http://stackoverflow.com'):void { 
      _dispatched = false; 
      _url = url; 
      _request = new URLRequest(url); 
      _loader.load(_request); 
      _log += 'load for ' + _url + ' started : ' + new Date() + '\n'; 
     } 

     private function _completeHandler(e:Event):void 
     { 
      _log += e.toString() + ' at ' + new Date(); 
      _isLive = true; 
      if (!_dispatched) { 
       dispatchEvent(_completeEvent); 
       _dispatched = true; 
      } 
     } 

     private function _httpStatusHandler(e:HTTPStatusEvent):void 
     { 
      /* comment this in when you're sure what statuses you're after 
      var statusesLen:int = _liveStatuses.length; 
      for (var i:int = statusesLen; i > 0; i--) { 
       if (e.status == _liveStatuses[i]) { 
        _isLive = true; 
        dispatchEvent(_completeEvent); 
       } 
      } 
      */ 
      //200 range 
      _log += e.toString() + ' at ' + new Date(); 
      if (e.status >= 200 && e.status < 300) _isLive = true; 
      else         _isLive = false; 
      if (!_dispatched) { 
       dispatchEvent(_completeEvent); 
       _dispatched = true; 
      } 
     } 

     private function _ioErrorEventHandler(e:IOErrorEvent):void 
     { 
      _log += e.toString() + ' at ' + new Date(); 
      _isLive = false; 
      if (!_dispatched) { 
       dispatchEvent(_completeEvent); 
       _dispatched = true; 
      } 
     } 

     private function _securityErrorHandler(e:SecurityErrorEvent):void 
     { 
      _log += e.toString() + ' at ' + new Date(); 
      _isLive = false; 
      if (!_dispatched) { 
       dispatchEvent(_completeEvent); 
       _dispatched = true; 
      } 
     } 

     public function get isLive():Boolean { return _isLive; } 

     public function get log():String { return _log; } 

    } 

} 

，這裏是一個基本的使用示例：

var urlChecker:URLChecker = new URLChecker(); 
urlChecker.addEventListener(Event.COMPLETE, urlChecked); 
urlChecker.check('wrong_place.url'); 

function urlChecked(event:Event):void { 
    trace('is Live: ' + event.target.isLive); 
    trace('log: ' + event.target.log); 
} 

的想法很簡單： 1.創建一個檢查 2.監聽COMPLETE事件（當結果爲 時觸發）3.在處理程序中檢查它是否存在並記錄它。

在HTTP specs中，200面積看起來不錯，但取決於您加載的內容，您可能需要 來調整類。此外，您還需要更好地處理安全/跨域問題，但至少這是一個開始。

HTH

Answer 2

一個重要的考慮是喬治的回答冷落是URLRequestMethod。如果有人試圖驗證相當大的文件（例如媒體文件）的存在，而不僅僅是網頁，那麼您需要確保將的method屬性設置爲URLRequestMethod.HEAD。

如HTTP1.1 Protocol指出：

HEAD方法是相同，除了在應答服務器不能返回一個消息體得到的。

因此，如果你真的只想驗證URL的存在，這是要走的路。

對於那些誰需要的代碼闡明：

var _request:URLRequest = URLRequest(url); 
_request.method = URLRequestMethod.HEAD; // bandwidth :) 

否則，喬治的回答是一個很好的參考點。

注：這個特殊的URLRequestMethod只適用於AIR。