編寫Excel VBA從Access中接收數據

Question

我正在編寫一個從Access數據庫中繪製的Excel工作應用程序。當用戶打開Excel工具時，數據表需要從我創建的Access數據庫填充其中一個工作表。我一直在Excel中編寫VBA代碼，並且收到運行時錯誤：「429」ActiveX組件無法創建對象。

其他問題都是從Access編寫的，但我相信我需要從Excel工作簿文件編寫的代碼。我寫的代碼位於Workbook_Open()函數中，以便在用戶打開文件時正確收集數據。非常感謝您的幫助。順便說一句，我使用Access 2007和Excel 2010

Private Sub Workbook_Open() 
    'Will fill the first listbox with data from the Access database 
    Dim DBFullName As String 
    Dim TableName As String 
    Dim FieldName As String 
    Dim TargetRande As String 

    DBFullName = "D:\Tool_Database\Tool_Database.mdb" 

    Dim db As DAO.Database, rs As Recordset 
    Dim intColIndex As Integer 

    Set TargetRange = Range("A1") 
    Set db = OpenDatabase(DBFullName) 
    Set rs = db.OpenRecordset("SELECT * FROM ToolNames WHERE Item = 'Tool'", dbReadOnly) 

    ' Write the field names 
    For intColIndex = 0 To rs.Fields.Count - 1 
     TargetRange.Offset(1, intColIndex).Value = rs.Fields(intColIndex).Name 
    Next 

    ' Write recordset 
    TargetRange.Offset(1, 0).CopyFromRecordset rs 

    Set rs = Nothing 
    db.Close 
    Set db = Nothing 
End Sub 

Answer 1

泰勒，你能爲我測試這段代碼嗎？如果你有任何錯誤，你會得到一個消息框。只需發佈消息框的快照。

'~~> Remove all references as the below code uses Late Binding with ADO. 

Private Sub Workbook_Open() 
      Dim cn As Object, rs As Object 
      Dim intColIndex As Integer 
      Dim DBFullName As String 
      Dim TargetRange As Range 

10  DBFullName = "D:\Tool_Database\Tool_Database.mdb" 

20  On Error GoTo Whoa 

30  Application.ScreenUpdating = False 

40  Set TargetRange = Sheets("Sheet1").Range("A1") 

50  Set cn = CreateObject("ADODB.Connection") 
60  cn.Open "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=" & DBFullName & ";" 

70  Set rs = CreateObject("ADODB.Recordset") 
80  rs.Open "SELECT * FROM ToolNames WHERE Item = 'Tool'", cn, , , adCmdText 

      ' Write the field names 
90  For intColIndex = 0 To rs.Fields.Count - 1 
100   TargetRange.Offset(1, intColIndex).Value = rs.Fields(intColIndex).Name 
110  Next 

      ' Write recordset 
120  TargetRange.Offset(1, 0).CopyFromRecordset rs 

LetsContinue: 
130  Application.ScreenUpdating = True 
140  On Error Resume Next 
150  rs.Close 
160  Set rs = Nothing 
170  cn.Close 
180  Set cn = Nothing 
190  On Error GoTo 0 
200  Exit Sub 
Whoa: 
210  MsgBox "Error Description :" & Err.Description & vbCrLf & _ 
      "Error at line  :" & Erl & vbCrLf & _ 
      "Error Number  :" & Err.Number 
220  Resume LetsContinue 
End Sub 

Answer 2

它的工作原理在我的機器上細（除了字段名得到由數據的第一行覆蓋 - 字段名稱的您可能意味着TargetRange.Offset（0 ，intColIndex））。

你有工具 - >參考...到M​​icrosoft DAO 3.6對象庫嗎？

您是否正在使用64位版本的Excel 2010（在「關於Microsoft Excel」部分的文件 - >幫助下檢查）？如果是這樣，舊版本的DAO庫將無法工作，並且您需要安裝適用於64位的64位ACE DAO庫。

Answer 3

DAO和ADO都包含記錄集對象類型。但是它們不兼容。您對rs對象變量的聲明不明確。

Dim db As DAO.Database, rs As Recordset 

一個潛在的問題是，如果你的項目包括對ADO參考，並參照的優先級高於你的DAO參考，rs會倒閉的ADO記錄集，而不是DAO記錄。

我不確定這是您看到的錯誤的原因。但是，如果rs是ADO記錄集，則設置rs至db.OpenRecordset(something)應該失敗，因爲OpenRecordset會返回DAO記錄集。

我想你應該申報改成這樣：

Dim db As DAO.Database, rs As DAO.Recordset 

即使這種變化不會解決你的問題，我建議你總是聲明Recordset對象變量時限定型...避免含糊不清。

如果這不是修復，請告訴我們您的代碼的哪一行觸發了您所看到的當前錯誤。

這裏是另一個紅旗：

Dim TargetRande As String 

以後你：

Set TargetRange = Range("A1") 

添加Option Explict到您的模塊的聲明部分。然後從VB編輯器的主菜單中選擇Debug-> Compile。該工作將突出顯示拼寫錯誤的變量名稱，並提醒您語法錯誤。