習慣性的Clojure方法在seq中尋找最頻繁的項目

Question

給定一系列項目，我想找到n個最頻繁的項目，按頻率降序排列。所以例如我想這個單元測試通過：

(fact "can find 2 most common items in a sequence" 
     (most-frequent-n 2 ["a" "bb" "a" "x" "bb" "ccc" "dddd" "dddd" "bb" "dddd" "bb"]) 
     => 
     '("bb" "dddd")) 

我對Clojure相當新，仍然試圖抓住標準庫。這是我想出的：

(defn- sort-by-val [s]  (sort-by val s)) 
(defn- first-elements [pairs] (map #(get % 0) pairs)) 

(defn most-frequent-n [n items] 
    "return the most common n items, e.g. 
    (most-frequent-n 2 [:a :b :a :d :x :b :c :d :d :b :d :b]) => 
     => (:d :b)" 
    (take n (-> 
      items    ; [:a :b :a :d :x :b :c :d :d :b :d :b] 
      frequencies   ; {:a 2, :b 4, :d 4, :x 1, :c 1} 
      seq     ; ([:a 2] [:b 4] [:d 4] [:x 1] [:c 1]) 
      sort-by-val   ; ([:x 1] [:c 1] [:a 2] [:b 4] [:d 4]) 
      reverse    ; ([:d 4] [:b 4] [:a 2] [:c 1] [:x 1]) 
      first-elements))) ; (:d :b :a :c :x) 

但是，這似乎是一個複雜的功能鏈，做一個相當普通的操作。有沒有更優雅或更習慣（或更有效率）的方式來做到這一點？

Answer 1

正如您已經發現的那樣，通常您會使用排序和頻率組合來獲取頻率排序列表。

(sort-by val (frequencies ["a" "bb" "a" "x" "bb" "ccc" "dddd" "dddd" "bb" "dddd" "bb"])) 
=> (["x" 1] ["ccc" 1] ["a" 2] ["dddd" 3] ["bb" 4]) 

然後你可以很容易地操縱這個來得到最低/最高頻率的項目。也許是這樣的：

(defn most-frequent-n [n items] 
    (->> items 
    frequencies 
    (sort-by val) 
    reverse 
    (take n) 
    (map first))) 

這又是非常相似的解決方案（除了你不巧妙地利用了->>宏需要的輔助功​​能）。

總的來說，我認爲你的解決方案非常好。不要擔心功能鏈 - 對於邏輯上相當複雜的概念來說，它實際上是一個非常短的解決方案。嘗試在C＃/ Java中編碼相同的東西，你會明白我的意思......