類型不匹配錯誤

Question

我是VBA新手，在下面的代碼中出現類型不匹配錯誤。

我得到整數j的錯誤。我已將其更改爲所有其他數據類型，但仍相同。

Private Sub CommandButton3_Click() 

    Dim rng1 As Range, rng2 As Range, i As Integer, j As Integer, k As Integer 

    Set rng1 = Range("A:A") 
    Set rng2 = Range("B:B") 

    j = Application.WorksheetFunction.Lookup(2, 1/(rng1 <> ""), rng1) 
    k = Application.WorksheetFunction.Match(j, rng1, 0) 

    i = 0 

    For i = i + 1 To k 
     If Cells(i, 1) Mod 2 = 0 Then 
      Cells(i, 2) = "Even" 
     Else: Cells(i, 2) = "Odd" 
     End If 
    Next i 

    MsgBox "There are " & Application.WorksheetFunction.CountIf(rng2, "Even") _ 
     & " Even and " & Application.WorksheetFunction.CountIf(rng2, "Odd") & " Odd numbers" 

End Sub 

Answer 1

我的評論：

如果我正確地讀你的代碼，你試圖找到一個包含與A列的最後佔用的行的值的第一行是正確的嗎？然後，您正在設法計算出至此爲止出現了多少個偶數以及多少個奇數 - 但是您希望從列中排除最後一個值的第一次出現以外的任何內容。是否正確？ ...

你的答案：

前兩個你的問題是完全正確的。

示例數據：

---

如果你真的想找到一個包含與在A列的最後佔用的行的值的第一行，即包含第一行3在上面的示例數據中，並確定該點的賠率/平均數，並從計數中排除超出該點的任何數值，然後您可以使用以下代碼：

Private Sub CommandButton3_Click()  
    Dim lastUsedRow As Long 
    Dim lastRow As Long 
    Dim i As Long 
    Dim Odds As Long: Odds = 0 
    Dim Evens As Long: Evens = 0 

    With ActiveSheet 

     'Find the last used row in column A (row 9 in example data) 
     lastUsedRow = .Cells(.Rows.Count, "A").End(xlUp).Row 

     'Find first row containing the data from the last used row 
     '(i.e. the first row containing a 3 in the example data, i.e. row 4) 
     lastRow = Application.Match(.Cells(lastUsedRow, "A").Value, .Range("A:A"), 0) 

     'Loop from first row to last row 
     For i = 1 To lastRow 

      'Decide whether the nearest integer to the value in the cell 
      'is odd or even 
      If .Cells(i, "A").Value Mod 2 = 0 Then 
       .Cells(i, "B").Value = "Even" 
       Evens = Evens + 1 
      Else 
       .Cells(i, "B").Value = "Odd" 
       Odds = Odds + 1 
      End If 

     Next i 

     MsgBox "There are " & Evens & " Even and " & Odds & " Odd numbers" 
    End With 
End Sub 

---

但是，如果你想要做的你的計算，那麼所有行，你可以使用下面的代碼：

Private Sub CommandButton3_Click()  
    Dim lastUsedRow As Long 
    Dim i As Long 
    Dim Odds As Long: Odds = 0 
    Dim Evens As Long: Evens = 0 

    With ActiveSheet 

     'Find the last used row in column A (row 9 in example data) 
     lastUsedRow = .Cells(.Rows.Count, "A").End(xlUp).Row 

     'Loop from first row to last used row 
     For i = 1 To lastUsedRow 

      'Decide whether the nearest integer to the value in the cell 
      'is odd or even 
      If .Cells(i, "A").Value Mod 2 = 0 Then 
       .Cells(i, "B").Value = "Even" 
       Evens = Evens + 1 
      Else 
       .Cells(i, "B").Value = "Odd" 
       Odds = Odds + 1 
      End If 

     Next i 

     MsgBox "There are " & Evens & " Even and " & Odds & " Odd numbers" 
    End With 
End Sub